[arch-commits] Commit in python-cffi/repos (2 files)

[Felix Yan]

    Date: Sunday, February 9, 2020 @ 09:13:37
  Author: felixonmars
Revision: 375030

archrelease: copy trunk to community-testing-x86_64

Added:
  python-cffi/repos/community-testing-x86_64/
  python-cffi/repos/community-testing-x86_64/PKGBUILD
    (from rev 375029, python-cffi/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-cffi/repos/community-testing-x86_64/PKGBUILD (from rev 375029, python-cffi/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-02-09 09:13:37 UTC (rev 375030)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: lilydjwg <lilydjwg at gmail.com>
+
+pkgbase=python-cffi
+pkgname=(python-cffi python2-cffi)
+pkgver=1.14.0
+pkgrel=1
+pkgdesc="Foreign Function Interface for Python calling C code"
+arch=('x86_64')
+url="https://cffi.readthedocs.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pycparser' 'python2-pycparser')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://bitbucket.org/cffi/cffi/get/v$pkgver.tar.gz")
+sha512sums=('4efe1933ddee9cfaf95dbc5c3c11278e50353b2d246d1fc7707442c48129317d21f6946e670219c2b6397b63093db4c3f421ecaa33d86f6b68007a6186e1b607')
+
+prepare() {
+  mv cffi-cffi-* cffi-$pkgver
+  cp -a cffi-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/cffi-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/cffi-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/cffi-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/cffi-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-cffi() {
+  depends=('python-pycparser')
+
+  cd cffi-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-cffi() {
+  depends=('python2-pycparser')
+
+  cd cffi-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}