[arch-commits] Commit in openshot/repos (2 files)

[David Runge]

    Date: Sunday, February 9, 2020 @ 19:41:13
  Author: dvzrv
Revision: 565530

archrelease: copy trunk to community-staging-any

Added:
  openshot/repos/community-staging-any/
  openshot/repos/community-staging-any/PKGBUILD
    (from rev 565529, openshot/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: openshot/repos/community-staging-any/PKGBUILD (from rev 565529, openshot/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-02-09 19:41:13 UTC (rev 565530)
@@ -0,0 +1,37 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Florian Pritz <bluewind at xinu.at>
+# Contributor: Asa Marco <marcoasa90[at]gmail[.]com>
+
+pkgname=openshot
+pkgver=2.5.0
+pkgrel=1
+pkgdesc="An award-winning free and open-source video editor"
+arch=('any')
+url="https://www.openshot.org/"
+license=('GPL3')
+depends=('ffmpeg' 'python-mlt' 'python-pyqt5' 'python-requests' 'libopenshot'
+'libopenshot-audio' 'python-pyzmq' 'qt5-base' 'qt5-svg' 'qt5-webkit')
+optdepends=('faac: for exporting audio using AAC')
+makedepends=('python-setuptools')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenShot/openshot-qt/archive/v$pkgver.tar.gz")
+sha512sums=('0944bff48c8957a4a3c5a37428b4d3e45e8ad6e1664812ea90b7c16d014a3c355daf2fe183ce855586114ccfa36c419b6baacc42c4bf871de29bda4c24f2a814')
+
+prepare() {
+  mv -v "${pkgname}-qt-${pkgver}" "${pkgname}-${pkgver}"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py install --skip-build \
+                          --optimize=1 \
+                          --prefix=/usr \
+                          --root="${pkgdir}"
+  install -vDm 644 {AUTHORS,{CONTRIBUTING,README}.md} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
+}