[arch-commits] Commit in haskell-http-api-data/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Feb 16 11:54:08 UTC 2020


    Date: Sunday, February 16, 2020 @ 11:54:08
  Author: felixonmars
Revision: 572375

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-api-data/repos/community-staging-x86_64/
  haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD
    (from rev 572374, haskell-http-api-data/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD (from rev 572374, haskell-http-api-data/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-16 11:54:08 UTC (rev 572375)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-api-data
+pkgname=haskell-http-api-data
+pkgver=0.4.1.1
+pkgrel=18
+pkgdesc="Converting to/from HTTP API data like URL pieces, headers and query parameters."
+url="https://github.com/fizruk/http-api-data"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-attoparsec-iso8601' 'haskell-base-compat'
+         'haskell-cookie' 'haskell-hashable' 'haskell-http-types' 'haskell-tagged'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-uuid-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('9b768dc790999e42a82753b69f6ab48df90721468eaff79bf4b9a1eb08572dba3488908db4ad0a1afb3956513a16fcd663f005856e230748f665987766e10c59')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/nats/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-use-text-show
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list