[arch-commits] Commit in haskell-haddock-library/repos (2 files)

[Felix Yan]

    Date: Sunday, February 16, 2020 @ 13:20:38
  Author: felixonmars
Revision: 572533

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-haddock-library/repos/community-staging-x86_64/
  haskell-haddock-library/repos/community-staging-x86_64/PKGBUILD
    (from rev 572532, haskell-haddock-library/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-haddock-library/repos/community-staging-x86_64/PKGBUILD (from rev 572532, haskell-haddock-library/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-16 13:20:38 UTC (rev 572533)
@@ -0,0 +1,43 @@
+# Maintainer: Sergej Pupykin <arch+pub at sergej.pp.ru>
+
+_hkgname=haddock-library
+pkgname=haskell-haddock-library
+pkgver=1.8.0
+pkgrel=21
+pkgdesc="A documentation-generation tool for Haskell libraries"
+url="https://www.haskell.org/haddock/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-hspec' 'haskell-hspec-discover'
+             'haskell-quickcheck' 'haskell-optparse-applicative' 'haskell-tree-diff')
+source=("https://hackage.haskell.org/packages/archive/haddock-library/${pkgver}/haddock-library-${pkgver}.tar.gz")
+sha512sums=('f84672b67dd4b18402efb8b40eb0e2cb912ecf894cfdedf61b0ada87392e63609cf1101d4fc793686cc4af354665661bf4dc902313bb466efee683a7c64bbe2b')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}