[arch-commits] Commit in haskell-mono-traversable-instances/repos (2 files)

[Felix Yan]

    Date: Sunday, February 16, 2020 @ 13:27:15
  Author: felixonmars
Revision: 572547

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-mono-traversable-instances/repos/community-staging-x86_64/
  haskell-mono-traversable-instances/repos/community-staging-x86_64/PKGBUILD
    (from rev 572546, haskell-mono-traversable-instances/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-mono-traversable-instances/repos/community-staging-x86_64/PKGBUILD (from rev 572546, haskell-mono-traversable-instances/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-16 13:27:15 UTC (rev 572547)
@@ -0,0 +1,48 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+
+_hkgname=mono-traversable-instances
+pkgname=haskell-mono-traversable-instances
+pkgver=0.1.0.0
+pkgrel=16
+pkgdesc='Extra typeclass instances for mono-traversable'
+arch=(x86_64)
+url="https://hackage.haskell.org/package/$_hkgname"
+license=(MIT)
+depends=(ghc-libs haskell-dlist haskell-comonad haskell-mono-traversable
+         haskell-semigroupoids haskell-vector-instances haskell-dlist-instances)
+makedepends=(ghc)
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('53eeb28d68769cc995a2abf4219e6ccbe211d53f190112bb3c6792a3591ccb6334691ec491d92563489d64c7f39df81b02c0a36178daff135fce8b8475f43d0b')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+      --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+      --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: