[arch-commits] Commit in cgns/repos (2 files)

[Bruno Pagani]

    Date: Monday, February 17, 2020 @ 15:07:22
  Author: archange
Revision: 574285

archrelease: copy trunk to community-staging-x86_64

Added:
  cgns/repos/community-staging-x86_64/
  cgns/repos/community-staging-x86_64/PKGBUILD
    (from rev 574284, cgns/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: cgns/repos/community-staging-x86_64/PKGBUILD (from rev 574284, cgns/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-17 15:07:22 UTC (rev 574285)
@@ -0,0 +1,48 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: eolianoe <eolianoe At GoogleMAIL DoT com>
+# Contriburor: Mathias Anselmann <mathias.anselmann at gmail.com>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: lainme <lainme993 at gmail.com>
+# Contributor: Klimov Max <cleemmi at gmail.com>
+
+_pkgname=CGNS
+pkgname=cgns
+pkgver=3.4.1
+pkgrel=1
+pkgdesc="Standard for recording and recovering computer data associated with the numerical solution of fluid dynamics equations"
+arch=(x86_64)
+url="https://cgns.github.io/"
+license=(custom)
+depends=(tk hdf5 libxmu glu)
+makedepends=(gcc-fortran cmake)
+options=(!makeflags)
+source=(https://github.com/${_pkgname}/${_pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('d32595e7737b9332243bd3de1eb8c018a272f620f09b289dea8292eba1365994')
+
+build() {
+    cmake -B build -S ${_pkgname}-${pkgver} \
+        -DCGNS_BUILD_CGNSTOOLS=ON \
+        -DCGNS_BUILD_SHARED=ON \
+        -DCGNS_ENABLE_64BIT=ON \
+        -DCGNS_ENABLE_FORTRAN=ON \
+        -DCGNS_ENABLE_HDF5=ON \
+        -DCGNS_ENABLE_LEGACY=ON \
+        -DCGNS_ENABLE_SCOPING=OFF \
+        -DCGNS_ENABLE_TESTS=ON \
+        -DHDF5_FOUND=OFF \
+        -DCMAKE_BUILD_TYPE="Release" \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_SKIP_RPATH=ON
+# HDF5_FOUND=OFF is a (silly) workaround for https://cgnsorg.atlassian.net/browse/CGNS-143
+    make -C build
+}
+
+
+check() {
+    make -C build test
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm644 ${_pkgname}-${pkgver}/license.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}