[arch-commits] Commit in libsecp256k1/repos (2 files)

[Bruno Pagani]

    Date: Monday, February 17, 2020 @ 16:43:15
  Author: archange
Revision: 574385

archrelease: copy trunk to community-staging-x86_64

Added:
  libsecp256k1/repos/community-staging-x86_64/
  libsecp256k1/repos/community-staging-x86_64/PKGBUILD
    (from rev 574384, libsecp256k1/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: libsecp256k1/repos/community-staging-x86_64/PKGBUILD (from rev 574384, libsecp256k1/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-17 16:43:15 UTC (rev 574385)
@@ -0,0 +1,51 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Baptiste Jonglez <archlinux at bitsofnetworks dot org>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgname=libsecp256k1
+_gitcommit=856a01d6ad60c70fd92bdd44fa8584493b87594d
+pkgver=20200210+1037+g856a01d
+pkgrel=1
+pkgdesc="Optimized C library for EC operations on curve secp256k1"
+arch=(x86_64)
+url="https://github.com/bitcoin-core/secp256k1"
+license=(MIT)
+depends=(gmp)
+source=(${url}/archive/${_gitcommit}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('5ba3ef13f849fa79d9493e580a3dc7f08b27d1e0e6080913063955ea9f88aec1')
+
+prepare() {
+  cd secp256k1-${_gitcommit}
+  autoreconf -vfi
+}
+
+build() {
+  cd secp256k1-${_gitcommit}
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/bin \
+    --sysconfdir=/etc \
+    --sharedstatedir=/usr/share/libsecp256k1 \
+    --localstatedir=/var/lib/libsecp256k1 \
+    --disable-static \
+    --disable-benchmark \
+    --disable-coverage \
+    --enable-module-recovery \
+    --enable-tests \
+    --enable-exhaustive-tests \
+    --disable-openssl-tests \
+    --with-gnu-ld
+  make
+}
+
+check() {
+  cd secp256k1-${_gitcommit}
+  make check
+}
+
+package() {
+  cd secp256k1-${_gitcommit}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}