[arch-commits] Commit in python-cftime/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Bruno Pagani]

    Date: Monday, February 17, 2020 @ 17:40:53
  Author: archange
Revision: 574461

archrelease: copy trunk to community-x86_64

Added:
  python-cftime/repos/community-x86_64/PKGBUILD
    (from rev 574460, python-cftime/trunk/PKGBUILD)
Deleted:
  python-cftime/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   70 ++++++++++++++++++++++---------------------------------------
 1 file changed, 26 insertions(+), 44 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-02-17 17:40:48 UTC (rev 574460)
+++ PKGBUILD	2020-02-17 17:40:53 UTC (rev 574461)
@@ -1,44 +0,0 @@
-# Maintainer: Bruno Pagani <archange at archlinux.org>
-
-_pkg=cftime
-pkgbase=python-${_pkg,,}
-pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
-pkgver=1.0.4.2
-pkgrel=3
-pkgdesc="Time-handling functionality from python-netcdf4"
-arch=(x86_64)
-url="https://unidata.github.io/cftime"
-license=(MIT)
-makedepends=(cython python-setuptools cython2 python2-setuptools python-numpy python2-numpy)
-source=("https://files.pythonhosted.org/packages/source/c/${_pkg}/${_pkg}-${pkgver}.tar.gz")
-sha256sums=('1ac64f8f9066ea756ea27d67cedaf064e7c866275218fa7c84684066a5890f70')
-
-prepare() {
-    cp -a ${_pkg}-${pkgver}{,-py2}
-}
-
-build() {
-    cd ${_pkg}-${pkgver}
-    python setup.py build
-
-    cd ../${_pkg}-${pkgver}-py2
-    python2 setup.py build
-}
-
-package_python-cftime() {
-    depends=(python-numpy)
-
-    cd ${_pkg}-${pkgver}
-    python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
-
-    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
-}
-
-package_python2-cftime() {
-    depends=(python2-numpy)
-
-    cd ${_pkg}-${pkgver}-py2
-    python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
-
-    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
-}

Copied: python-cftime/repos/community-x86_64/PKGBUILD (from rev 574460, python-cftime/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-02-17 17:40:53 UTC (rev 574461)
@@ -0,0 +1,26 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=cftime
+pkgname=python-${_pkg}
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Time-handling functionality from python-netcdf4"
+arch=(x86_64)
+url="https://unidata.github.io/cftime"
+license=(MIT)
+depends=(python-numpy)
+makedepends=(cython python-setuptools)
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(https://github.com/Unidata/cftime/archive/v${pkgver}rel/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('ed814ca8d1ef155f4fa8c3a4dcf7449922704b20ce9532c8da0c054c20ed3532')
+
+build() {
+    cd ${_pkg}-${pkgver}rel
+    python setup.py build
+}
+
+package() {
+    cd ${_pkg}-${pkgver}rel
+    python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}