[arch-commits] Commit in hledger/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Feb 17 23:52:45 UTC 2020


    Date: Monday, February 17, 2020 @ 23:52:44
  Author: felixonmars
Revision: 575619

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger/repos/community-staging-x86_64/
  hledger/repos/community-staging-x86_64/PKGBUILD
    (from rev 575618, hledger/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: hledger/repos/community-staging-x86_64/PKGBUILD (from rev 575618, hledger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-17 23:52:44 UTC (rev 575619)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger
+pkgver=1.16.2
+pkgrel=4
+pkgdesc="Command-line interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-base-compat-batteries' 'haskell-cmdargs'
+         'haskell-data-default' 'haskell-decimal' 'haskell-diff' 'haskell-hashable'
+         'haskell-hledger-lib' 'haskell-lucid' 'haskell-math-functions' 'haskell-megaparsec'
+         'haskell-old-time' 'haskell-pretty-show' 'haskell-regex-tdfa' 'haskell-safe'
+         'haskell-shakespeare' 'haskell-split' 'haskell-tabular' 'haskell-tasty'
+         'haskell-temporary' 'haskell-unordered-containers' 'haskell-utf8-string'
+         'haskell-utility-ht' 'haskell-wizards')
+makedepends=('ghc' 'haskell-extra' 'haskell-timeit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('efd03857ce1ae15d221176ade334caecc72e89d35f695594cb52d54b291dc7e7c291b6354f237a2334e8446f0a318ecd19fc4867dc6af029142159d1493474cb')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fterminfo -fthreaded --ghc-option='-pie'
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list