[arch-commits] Commit in kup/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Wed Feb 19 17:53:42 UTC 2020
Date: Wednesday, February 19, 2020 @ 17:53:41
Author: arojas
Revision: 576728
archrelease: copy trunk to community-staging-x86_64
Added:
kup/repos/community-staging-x86_64/
kup/repos/community-staging-x86_64/PKGBUILD
(from rev 576727, kup/trunk/PKGBUILD)
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Copied: kup/repos/community-staging-x86_64/PKGBUILD (from rev 576727, kup/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2020-02-19 17:53:41 UTC (rev 576728)
@@ -0,0 +1,41 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: XavierCLL <xavier.corredor.llano (a) gmail.com>
+# PKGBUILD base; Simper < simonpersson1 AT gmail DOT com >
+
+pkgname=kup
+pkgver=0.7.3
+pkgrel=4
+pkgdesc="A KDE bup backup software for helping people to keep up-to-date backups"
+arch=(x86_64)
+url="https://www.linux-apps.com/p/1127689/"
+license=(GPL2)
+depends=(kidletime kinit libgit2 hicolor-icon-theme)
+makedepends=(extra-cmake-modules plasma-framework)
+optdepends=('bup: support for incremental backups'
+ 'rsync: support for synced backups')
+source=("https://github.com/spersson/Kup/archive/$pkgname-$pkgver.tar.gz"
+ kup-cmake-build-type.patch::"https://patch-diff.githubusercontent.com/raw/spersson/Kup/pull/81.patch")
+sha256sums=('47b97314dd11579a6ecc723de687c9ebe7cafb300d2ce39f2510d36c17de2f3b'
+ '5ba2786dc43436774f24c72ca7abdc887bdf7e739bfe97b71f89c64912441f99')
+
+prepare() {
+ mkdir -p build
+
+ cd Kup-$pkgname-$pkgver
+ patch -p1 -i ../kup-cmake-build-type.patch # Fix build when CMAKE_BUILD_TYPE is not specified
+}
+
+build() {
+ cd build
+ cmake ../Kup-$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DUSE_SYSTEM_LIBGIT2=ON \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list