[arch-commits] Commit in python-qdarkstyle/repos (2 files)
Bruno Pagani
archange at archlinux.org
Thu Feb 20 18:31:52 UTC 2020
Date: Thursday, February 20, 2020 @ 18:31:52
Author: archange
Revision: 577302
archrelease: copy trunk to community-any
Added:
python-qdarkstyle/repos/community-any/
python-qdarkstyle/repos/community-any/PKGBUILD
(from rev 577301, python-qdarkstyle/trunk/PKGBUILD)
----------+
PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
1 file changed, 36 insertions(+)
Copied: python-qdarkstyle/repos/community-any/PKGBUILD (from rev 577301, python-qdarkstyle/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2020-02-20 18:31:52 UTC (rev 577302)
@@ -0,0 +1,36 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=QDarkStyle
+pkgname=python-${_pkg,,}
+pkgver=2.8
+pkgrel=1
+pkgdesc="Dark style sheet for QtWidgets application"
+arch=(any)
+url="https://github.com/ColinDuquesnoy/QDarkStyleSheet"
+license=(MIT CCPL)
+depends=(python-helpdev python-qtpy)
+makedepends=(python-setuptools)
+checkdepends=(python-pyqt5 pyside2)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('6a967c4b664446f8bed9df12d1032cf68cb54f186bfc9cbfdbbc756bf9a5d475')
+
+build() {
+ cd ${_pkg}-${pkgver}
+ python setup.py build
+}
+
+check() {
+ cd ${_pkg}-${pkgver}
+ # PyQt5 tests
+ python example/example.py --qt_from=pyqt5 --test
+ python example/example.py --qt_from=pyqt5 --test --no_dark
+ # PySide2 tests
+ python example/example.py --qt_from=pyside2 --test
+ python example/example.py --qt_from=pyside2 --test --no_dark
+}
+
+package() {
+ cd ${_pkg}-${pkgver}
+ python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+ install -Dm644 LICENSE.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list