[arch-commits] Commit in (4 files)
Bruno Pagani
archange at archlinux.org
Fri Feb 21 00:10:43 UTC 2020
Date: Friday, February 21, 2020 @ 00:10:41
Author: archange
Revision: 577442
Initial addition of python-mss to [community]
checkdepends for python-pyscreenshot
Added:
python-mss/
python-mss/repos/
python-mss/trunk/
python-mss/trunk/PKGBUILD
----------+
PKGBUILD | 33 +++++++++++++++++++++++++++++++++
1 file changed, 33 insertions(+)
Added: python-mss/trunk/PKGBUILD
===================================================================
--- python-mss/trunk/PKGBUILD (rev 0)
+++ python-mss/trunk/PKGBUILD 2020-02-21 00:10:41 UTC (rev 577442)
@@ -0,0 +1,33 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=mss
+pkgname=python-${_pkg}
+pkgver=5.0.0
+pkgrel=1
+pkgdesc="Ultra fast cross-platform multiple screenshots module"
+arch=(any)
+url="https://github.com/BoboTiG/python-mss"
+license=(MIT)
+depends=(python)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest xorg-server-xvfb libxrandr lsof)
+#PyPi tarball lacks a test data
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('d14906907423d1977f24998b8f62e368e8c1133b0164755dd569f48e7c95b9c4')
+
+build() {
+ cd ${pkgname}-${pkgver}
+ python setup.py build
+}
+
+check() {
+ cd ${pkgname}-${pkgver}
+ PYTHONPATH="${PWD}/build/lib/" xvfb-run -a -s "+extension RANDR +render -screen 0 1024x768x24" pytest
+}
+
+package() {
+ cd ${pkgname}-${pkgver}
+ python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+ install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list