[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Friday, February 21, 2020 @ 01:21:23
  Author: archange
Revision: 577472

Initial addition of python-entrypoint2 to [community]

depends of python-pyscreenshot
checkdepends of python-pyvirtualdisplay

Added:
  python-entrypoint2/
  python-entrypoint2/repos/
  python-entrypoint2/trunk/
  python-entrypoint2/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: python-entrypoint2/trunk/PKGBUILD
===================================================================
--- python-entrypoint2/trunk/PKGBUILD	                        (rev 0)
+++ python-entrypoint2/trunk/PKGBUILD	2020-02-21 01:21:23 UTC (rev 577472)
@@ -0,0 +1,33 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=entrypoint2
+pkgname=python-${_pkg}
+pkgver=0.2
+pkgrel=1
+pkgdesc="Easy to use command-line interface for python modules"
+arch=(any)
+url="https://github.com/ponty/entrypoint2"
+license=(BSD)
+depends=(python-argparse python-decorator)
+makedepends=(python-setuptools)
+checkdepends=(python-nose python-path.py python-easyprocess)
+#PyPi tarball does not have tests, see https://github.com/ponty/entrypoint2/pull/5
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('a49b160c452914b830135201e6db466c6bb39759ccd0c301cbb7943ab57802fd')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}/tests
+  PYTHONPATH="../build/lib/" nosetests -vv
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}