[arch-commits] Commit in python-pyvirtualdisplay/repos (2 files)
Bruno Pagani
archange at archlinux.org
Fri Feb 21 01:24:14 UTC 2020
Date: Friday, February 21, 2020 @ 01:24:13
Author: archange
Revision: 577477
archrelease: copy trunk to community-any
Added:
python-pyvirtualdisplay/repos/community-any/
python-pyvirtualdisplay/repos/community-any/PKGBUILD
(from rev 577476, python-pyvirtualdisplay/trunk/PKGBUILD)
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Copied: python-pyvirtualdisplay/repos/community-any/PKGBUILD (from rev 577476, python-pyvirtualdisplay/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2020-02-21 01:24:13 UTC (rev 577477)
@@ -0,0 +1,38 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=PyVirtualDisplay
+pkgname=python-${_pkg,,}
+pkgver=0.2.5
+pkgrel=1
+pkgdesc="Python wrapper for Xvfb, Xephyr and Xvnc"
+arch=(any)
+url="https://github.com/ponty/PyVirtualDisplay"
+license=(BSD)
+depends=(python-easyprocess)
+makedepends=(python-setuptools)
+checkdepends=(
+ python-pytest python-nose python-pyscreenshot python-pillow
+ python-entrypoint2 python-path.py xorg-server-xvfb xorg-server-xephyr
+ xorg-xmessage xorg-xdpyinfo scrot
+)
+#PyPi tarball does not have tests https://github.com/ponty/PyVirtualDisplay/pull/45
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('30c13528871d032aec9c09b3a84452cb1d4f0dfc00a8f981df8bfa011b96e073')
+
+build() {
+ cd ${_pkg}-${pkgver}
+ python setup.py build
+}
+
+check() {
+ cd ${_pkg}-${pkgver}
+ # Test.test_slowshot and Test.test_slowshot_wrap are timing out
+ PYTHONPATH="${PWD}/build/lib" pytest tests || warning "Tests failed"
+}
+
+package() {
+ cd ${_pkg}-${pkgver}
+ python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+ install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list