[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 21, 2020 @ 13:25:54
  Author: felixonmars
Revision: 577514

addpkg: haskell-ghc-lib-parser-ex 8.8.2-1

Added:
  haskell-ghc-lib-parser-ex/
  haskell-ghc-lib-parser-ex/repos/
  haskell-ghc-lib-parser-ex/trunk/
  haskell-ghc-lib-parser-ex/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: haskell-ghc-lib-parser-ex/trunk/PKGBUILD
===================================================================
--- haskell-ghc-lib-parser-ex/trunk/PKGBUILD	                        (rev 0)
+++ haskell-ghc-lib-parser-ex/trunk/PKGBUILD	2020-02-21 13:25:54 UTC (rev 577514)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ghc-lib-parser-ex
+pkgname=haskell-ghc-lib-parser-ex
+pkgver=8.8.2
+pkgrel=1
+pkgdesc="Algorithms on GHC parse trees"
+url="https://github.com/shayne-fletcher/ghc-lib-parser-ex"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-uniplate' 'haskell-ghc')
+makedepends=('ghc' 'haskell-extra' 'haskell-tasty' 'haskell-tasty-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('956e2edab9284a9bb309a3b9689bb7c1080f8b6578c8842273075ddd65c7a7986b5666278aa70dd23c942feccb9512e2970783113f9b8deac6a03020e7b9466f')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}