[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 21, 2020 @ 17:14:48
  Author: felixonmars
Revision: 577791

addpkg: haskell-template-haskell-compat-v0208 0.1.2.1-1

Added:
  haskell-template-haskell-compat-v0208/
  haskell-template-haskell-compat-v0208/repos/
  haskell-template-haskell-compat-v0208/trunk/
  haskell-template-haskell-compat-v0208/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: haskell-template-haskell-compat-v0208/trunk/PKGBUILD
===================================================================
--- haskell-template-haskell-compat-v0208/trunk/PKGBUILD	                        (rev 0)
+++ haskell-template-haskell-compat-v0208/trunk/PKGBUILD	2020-02-21 17:14:48 UTC (rev 577791)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=template-haskell-compat-v0208
+pkgname=haskell-template-haskell-compat-v0208
+pkgver=0.1.2.1
+pkgrel=1
+pkgdesc="A backwards compatibility layer for Template Haskell newer than 2.8"
+url="https://github.com/nikita-volkov/template-haskell-compat-v0208"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('864cfb6a9fdd24f9a17d6e9ed2dcf8b00c6dc289165b2f34fb90384a90c03f554705437e15f87d53cd532c78243bf89f141d93a880aaeb7c6af9dc51e85ac96f')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}