[arch-commits] Commit in (5 files)

Alexander Rødseth arodseth at archlinux.org
Tue Feb 25 23:00:03 UTC 2020


    Date: Tuesday, February 25, 2020 @ 23:00:03
  Author: arodseth
Revision: 582175

Add byobu, 308 votes in AUR

GPL3 licensed

Added:
  byobu/
  byobu/repos/
  byobu/repos/community-any/
  byobu/trunk/
  byobu/trunk/PKGBUILD

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Added: byobu/trunk/PKGBUILD
===================================================================
--- byobu/trunk/PKGBUILD	                        (rev 0)
+++ byobu/trunk/PKGBUILD	2020-02-25 23:00:03 UTC (rev 582175)
@@ -0,0 +1,55 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Daniel Landau <aur at landau.fi>
+# Contributor: Justin Coffman <jcoffman at datasecu dot red>
+# Contributor: Sibren Vasse <arch at sibrenvasse dot nl>
+# Contributor: oozyslug <oozyslug at gmail dot com>
+# Contributor: Justin Coffman <jcoffman at datasecu dot red>
+
+pkgname=byobu
+pkgver=5.133
+pkgrel=1
+pkgdesc='Enhanced tmux'
+arch=(any)
+url='https://byobu.org/'
+license=(GPL3)
+depends=(python tmux)
+makedepends=(gettext libnewt setconf)
+source=("$pkgname-$pkgver.tar.gz::https://launchpad.net/byobu/trunk/$pkgver/+download/byobu_$pkgver.orig.tar.gz"
+        "$pkgname-$pkgver.tar.gz.asc::https://launchpad.net/byobu/trunk/$pkgver/+download/..-byobu_$pkgver.orig.tar.gz.asc")
+sha256sums=('4d8ea48f8c059e56f7174df89b04a08c32286bae5a21562c5c6f61be6dab7563'
+            'SKIP')
+validpgpkeys=('E2D9E1C5F9F5D59291F4607D95E64373F1529469') # Dustin Kirkland <kirkland at ubuntu.com>
+
+prepare() {
+  # Adjust path to SOCKETDIR
+  setconf "$pkgname-$pkgver/etc/byobu/socketdir" SOCKETDIR '"/tmp/screens"'
+
+  # Tweak the two .desktop files that comes with Byobu
+  cd "$pkgname-$pkgver/usr/share/byobu/desktop"
+  setconf byobu.desktop Name 'Byobu Gnome Terminal'
+  setconf byobu.desktop Icon=/usr/share/byobu/pixmaps/byobu.svg
+  setconf byobu.desktop \
+    Exec "gnome-terminal --name=us.kirkland.terminals.byobu --class=us.kirkland.terminals.byobu -- byobu"
+  setconf byobu.desktop.old Icon=/usr/share/byobu/pixmaps/byobu.svg
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure --prefix=/usr --sysconfdir=/etc
+  make
+}
+
+package() {
+  DESTDIR="$pkgdir" make -C "$pkgname-$pkgver" install
+
+  # Move .desktop files to /usr/share/applications
+  install -d "$pkgdir/usr/share/applications"
+  mv "$pkgdir/usr/share/byobu/desktop/byobu.desktop" \
+    "$pkgdir/usr/share/applications/byobu.desktop"
+  mv "$pkgdir/usr/share/byobu/desktop/byobu.desktop.old" \
+    "$pkgdir/usr/share/applications/byobu_old.desktop"
+  rmdir "$pkgdir/usr/share/byobu/desktop"
+}
+
+# getver: launchpad.net/byobu/+download
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list