[arch-commits] Commit in python-hunter/repos (2 files)

[Felix Yan]

    Date: Thursday, February 27, 2020 @ 08:55:45
  Author: felixonmars
Revision: 583661

archrelease: copy trunk to community-testing-x86_64

Added:
  python-hunter/repos/community-testing-x86_64/
  python-hunter/repos/community-testing-x86_64/PKGBUILD
    (from rev 583660, python-hunter/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-hunter/repos/community-testing-x86_64/PKGBUILD (from rev 583660, python-hunter/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-02-27 08:55:45 UTC (rev 583661)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-hunter
+pkgver=3.1.0
+pkgrel=1
+arch=('x86_64')
+pkgdesc='Hunter is a flexible code tracing toolkit'
+license=('BSD')
+url='https://github.com/ionelmc/python-hunter'
+depends=('python-manhole' 'python-colorama')
+optdepends=('gdb: for remote support')
+makedepends=('python-setuptools' 'python-manhole' 'python-colorama' 'cython')
+checkdepends=('python-pytest-benchmark' 'python-virtualenv' 'python-pytest-runner' 'gdb'
+              'python-process-tests' 'python-aspectlib')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/ionelmc/python-hunter/archive/v$pkgver.tar.gz")
+sha512sums=('fac5e82316d0f7ff9650093338d06ee6a2cb16c0bdf3da544d9707b77e23d13a2a54c7d68b7bc22a0feb938673e75527679b7dc07b0f6232ae79d7f4f6960dda')
+
+prepare() {
+  rm python-hunter-$pkgver/src/hunter/*.c
+}
+
+build() {
+  cd "$srcdir"/python-hunter-$pkgver
+  python setup.py build
+}
+
+check() {
+  # Hack to process .pth files properly
+  # ptrace needed to pass the remote tests
+
+  cd "$srcdir"/python-hunter-$pkgver
+  virtualenv "$srcdir/pyvenv" --system-site-packages
+  (
+    . "$srcdir/pyvenv/bin/activate"
+    python setup.py install
+    python setup.py pytest
+  ) || warning "Tests failed"
+}
+
+package() {
+  cd python-hunter-$pkgver
+  python setup.py install --root "$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}