[arch-commits] Commit in haskell-bifunctors/repos (2 files)

[Felix Yan]

    Date: Thursday, February 27, 2020 @ 13:07:02
  Author: felixonmars
Revision: 584004

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-bifunctors/repos/community-staging-x86_64/
  haskell-bifunctors/repos/community-staging-x86_64/PKGBUILD
    (from rev 584003, haskell-bifunctors/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-bifunctors/repos/community-staging-x86_64/PKGBUILD (from rev 584003, haskell-bifunctors/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-27 13:07:02 UTC (rev 584004)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=bifunctors
+pkgname=haskell-bifunctors
+pkgver=5.5.7
+pkgrel=8
+pkgdesc="Bifunctors"
+url="https://github.com/ekmett/bifunctors/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-comonad' 'haskell-tagged'
+         'haskell-th-abstraction')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ea1632c5dc2b8d0735e3076337768bf595071d0245b85f80859dab09189d813473b574b17d5b49864bda8c2cccd348c99db0b9b890f563ecfb5f750b06a4b219')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -ftagged -f-semigroups
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}