[arch-commits] Commit in xmonad-contrib/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Feb 28 09:17:09 UTC 2020


    Date: Friday, February 28, 2020 @ 09:17:09
  Author: felixonmars
Revision: 584995

archrelease: copy trunk to community-staging-x86_64

Added:
  xmonad-contrib/repos/community-staging-x86_64/
  xmonad-contrib/repos/community-staging-x86_64/PKGBUILD
    (from rev 584994, xmonad-contrib/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: xmonad-contrib/repos/community-staging-x86_64/PKGBUILD (from rev 584994, xmonad-contrib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-28 09:17:09 UTC (rev 584995)
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Vesa Kaihlavirta <vegai at iki.fi>
+# Contributor: orbisvicis <gmail.com>
+
+pkgname=xmonad-contrib
+pkgver=0.16
+pkgrel=15
+pkgdesc='Add-ons for xmonad'
+url='https://xmonad.org/'
+arch=('x86_64')
+license=('BSD')
+depends=('ghc-libs' 'xmonad' 'sh' 'haskell-x11' 'haskell-x11-xft' 'haskell-utf8-string' 'haskell-random'
+         'haskell-old-time')
+makedepends=('ghc')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/xmonad/xmonad-contrib/archive/v${pkgver}.tar.gz)
+sha512sums=('68f93ef6bcc1f2b3f5422c35a9ddcf846c75c1e9d8e6177750f4fad8dec818642e0a7159d295a381f0656c85b1f52382af1e32d577a825c4fcbdfa4c131581cc')
+
+prepare() {
+  sed -i -e '/semigroups/d' -e 's/utf8-string,/utf8-string/' ${pkgname}-${pkgver}/${pkgname}.cabal
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  runhaskell Setup.lhs configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+             --prefix=/usr -fuse_xft --libsubdir=\$compiler/site-local/\$pkgid \
+             --docdir=/usr/share/doc/${pkgname}
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  install -Dm 744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+  install -Dm 744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+  runhaskell Setup.lhs copy --destdir="${pkgdir}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}



More information about the arch-commits mailing list