[arch-commits] Commit in haskell-fold-debounce/repos (2 files)

[Jelle van der Waa]

    Date: Friday, January 3, 2020 @ 21:50:30
  Author: jelle
Revision: 547761

archrelease: copy trunk to community-x86_64

Added:
  haskell-fold-debounce/repos/community-x86_64/
  haskell-fold-debounce/repos/community-x86_64/PKGBUILD
    (from rev 547760, haskell-fold-debounce/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-fold-debounce/repos/community-x86_64/PKGBUILD (from rev 547760, haskell-fold-debounce/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-01-03 21:50:30 UTC (rev 547761)
@@ -0,0 +1,43 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+
+_pkgname=fold-debounce
+pkgname=haskell-fold-debounce
+pkgver=0.2.0.9
+pkgrel=1
+pkgdesc='Fold multiple events that happen in a given period of time'
+arch=(x86_64)
+url='https://hackage.haskell.org/package/$_pkgname'
+license=(BSD)
+depends=(ghc-libs haskell-stm haskell-stm-delay haskell-data-default-class)
+checkdepends=(haskell-hspec)
+makedepends=(ghc)
+source=("https://hackage.haskell.org/packages/archive/$_pkgname/$pkgver/$_pkgname-$pkgver.tar.gz")
+sha512sums=('a7d23a153c9bc06c2371c5df49f14f6f673328b7ec2528f142a2becc4b77e0d392000018a637909c4e8808acce91e3001c046064c4b7cb30442d2171782aa19e')
+
+build() {
+  cd $_pkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+      --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+      --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_pkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: