[arch-commits] Commit in haskell-yesod/repos (2 files)

[Felix Yan]

    Date: Sunday, January 5, 2020 @ 02:53:53
  Author: felixonmars
Revision: 548772

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod/repos/community-staging-x86_64/
  haskell-yesod/repos/community-staging-x86_64/PKGBUILD
    (from rev 548771, haskell-yesod/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-yesod/repos/community-staging-x86_64/PKGBUILD (from rev 548771, haskell-yesod/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-01-05 02:53:53 UTC (rev 548772)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod
+pkgname=haskell-yesod
+pkgver=1.6.0
+pkgrel=398
+pkgdesc="Creation of type-safe, RESTful web applications."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-blaze-html' 'haskell-blaze-markup'
+         'haskell-data-default-class' 'haskell-fast-logger' 'haskell-monad-logger'
+         'haskell-resourcet' 'haskell-shakespeare' 'haskell-streaming-commons'
+         'haskell-unordered-containers' 'haskell-wai' 'haskell-wai-extra' 'haskell-wai-logger'
+         'haskell-warp' 'haskell-yaml' 'haskell-yesod-core' 'haskell-yesod-form'
+         'haskell-yesod-persistent')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('36caa5ee5c27a2355aff9e5dc210100661670717e251bb42bac48c02cd6979c38ae7b5fda1dd2e264aefb7b5b3808f7ccc9e511fd38b6de7090e16c7a91e1b15')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}