[arch-commits] Commit in inkscape/repos (3 files)

[Felix Yan]

    Date: Tuesday, January 7, 2020 @ 22:46:03
  Author: felixonmars
Revision: 372787

archrelease: copy trunk to staging-x86_64

Added:
  inkscape/repos/staging-x86_64/
  inkscape/repos/staging-x86_64/PKGBUILD
    (from rev 372786, inkscape/trunk/PKGBUILD)
  inkscape/repos/staging-x86_64/PKGBUILD.cmake
    (from rev 372786, inkscape/trunk/PKGBUILD.cmake)

----------------+
 PKGBUILD       |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 PKGBUILD.cmake |   61 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 134 insertions(+)

Copied: inkscape/repos/staging-x86_64/PKGBUILD (from rev 372786, inkscape/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-01-07 22:46:03 UTC (rev 372787)
@@ -0,0 +1,73 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=inkscape
+pkgver=0.92.4
+pkgrel=10
+pkgdesc='Professional vector graphics editor'
+url='https://inkscape.org/'
+license=('GPL' 'LGPL')
+arch=('x86_64')
+depends=('gc' 'gsl' 'gtkmm' 'gtkspell' 'libmagick6' 'libxslt' 'poppler-glib'
+         'popt' 'potrace' 'ttf-dejavu' 'python2' 'libcdr'
+         'desktop-file-utils' 'hicolor-icon-theme')
+# python is needed for glib-genmarshal (at least with GLib 2.54)
+makedepends=('boost' 'intltool' 'python')
+optdepends=('gvfs: import clip art'
+            'pstoedit: latex formulas'
+            'python2-scour: optimized SVG output'
+            'texlive-core: latex formulas'
+            'python2-numpy: some extensions'
+            'python2-lxml: some extensions and filters')
+source=("https://media.inkscape.org/dl/resources/file/${pkgname}-${pkgver}.tar.bz2")
+sha256sums=('57ec2da8177b36614a513e2822efd73af721e690f7ddc6bd0a5fbb1525b4515e')
+
+# NB: Some CDN nodes appear to be distributing an outdated version of this file.
+
+prepare() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	./autogen.sh
+
+	sed -i 's|/usr/bin/python\>|/usr/bin/python2|g' cxxtest/*.py
+	sed -i 's|/usr/bin/env python\>|/usr/bin/env python2|g' share/*/{test/,}*.py
+	sed -i 's|"python" },|"python2" },|g' src/extension/implementation/script.cpp
+	sed -i 's|python -c|python2 -c|g' configure share/extensions/uniconv*.py
+	sed -i 's|"python"|"python2"|g' src/main.cpp
+
+	sed -i 's| abs(| std::fabs(|g' src/ui/tools/flood-tool.cpp
+       # Fix build with poppler 0.71
+        sed -e 's|gTrue|true|g' -e 's|gFalse|false|g' -e 's|GBool|bool|g' -i src/extension/internal/pdfinput/pdf-parser.*
+       # Fix build with poppler 0.72
+        sed -e 's|getCString|c_str|g' -i src/extension/internal/pdfinput/*
+       # Fix build with poppler 0.76
+        sed -e 's|new Lexer(xref, obj)|obj|g' -i src/extension/internal/pdfinput/pdf-parser.cpp
+       # Fix build with poppler 0.82
+        sed -e 's|Unicode \*u|Unicode const *u|g' -i src/extension/internal/pdfinput/*
+       # Fix build with poppler 0.83
+        sed -e 's|(GfxPath|(const GfxPath|g' -e 's|GfxSubpath|const GfxSubpath|g' \
+          -e 's|new GlobalParams()|std::unique_ptr<GlobalParams>(new GlobalParams())|g' \
+          -e 's|new GlobalParams(poppler_datadir)|std::unique_ptr<GlobalParams>(new GlobalParams(poppler_datadir))|g' \
+          -i src/extension/internal/pdfinput/*.cpp
+}
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	export PKG_CONFIG_PATH='/usr/lib/imagemagick6/pkgconfig'
+	export FREETYPE_CONFIG="/usr/bin/pkg-config freetype2"
+
+	./configure \
+		--prefix=/usr \
+		--with-python \
+		--with-perl \
+		--enable-lcms \
+		--enable-poppler-cairo \
+		--disable-strict-build \
+		--disable-dependency-tracking
+	make
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+}

Copied: inkscape/repos/staging-x86_64/PKGBUILD.cmake (from rev 372786, inkscape/trunk/PKGBUILD.cmake)
===================================================================
--- staging-x86_64/PKGBUILD.cmake	                        (rev 0)
+++ staging-x86_64/PKGBUILD.cmake	2020-01-07 22:46:03 UTC (rev 372787)
@@ -0,0 +1,61 @@
+# $Id: PKGBUILD 305444 2017-09-13 20:29:19Z andyrtr $
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=inkscape
+pkgver=0.92.2
+pkgrel=3
+pkgdesc='Professional vector graphics editor'
+url='https://inkscape.org/'
+license=('GPL' 'LGPL')
+arch=('x86_64')
+makedepends=('boost' 'intltool' 'cmake')
+depends=('gc' 'gsl' 'gtkmm' 'gtkspell' 'imagemagick' 'libxslt' 'poppler-glib'
+         'popt' 'potrace' 'ttf-dejavu' 'python' 'libcdr' 'libvisio' 'libwpg'
+         'desktop-file-utils' 'hicolor-icon-theme')
+optdepends=('gvfs: import clip art'
+            'pstoedit: latex formulas'
+            'scour: optimized SVG output'
+            'texlive-core: latex formulas'
+            'python-numpy: some extensions'
+            'python-lxml: some extensions and filters'
+            'uniconvertor: reading/writing to some proprietary formats')
+source=("https://media.inkscape.org/dl/resources/file/${pkgname}-${pkgver}.tar.bz2"
+        poppler-0.58.patch)
+sha256sums=('a628d0e04c254e9840947e6d866974f92c68ae31631a38b94d9b65e5cd84cfd3'
+            'af6796619a74b392432c72abdb703971fbcaf1c8ff196ce5bb37505914d38f5a')
+
+# NB: Some CDN nodes appear to be distributing an outdated version of this file.
+
+prepare() {
+	cd ${pkgname}-${pkgver}
+
+	mkdir ../build
+
+	# https://gitlab.com/inkscape/inkscape/commit/93ccf03162cd2e46d962822d5507865f3451168c
+	patch -Np1 -i ../poppler-0.58.patch
+}
+
+build() {
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+	  -DCMAKE_BUILD_TYPE=Release \
+	  -DCMAKE_INSTALL_PREFIX:PATH=/usr \
+	  -DINCLUDE_INSTALL_DIR:PATH=/usr/include \
+	  -DLIB_INSTALL_DIR:PATH=/usr/lib \
+	  -DSYSCONF_INSTALL_DIR:PATH=/etc \
+	  -DSHARE_INSTALL_PREFIX:PATH=/usr/share \
+	  -DCMAKE_ENABLE_LCMS=ON \
+	  -DCMAKE_ENABLE_POPPLER_CAIRO=ON \
+	  -DCMAKE_WITH_NLS=ON
+	make
+}
+
+package() {
+	cd build
+	make DESTDIR="${pkgdir}" install
+
+	# cleanup
+	rm $pkgdir/usr/include/*.a
+}