[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, January 8, 2020 @ 13:57:02
  Author: felixonmars
Revision: 550287

addpkg: haskell-hint 0.9.0.2-1

Added:
  haskell-hint/
  haskell-hint/repos/
  haskell-hint/trunk/
  haskell-hint/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: haskell-hint/trunk/PKGBUILD
===================================================================
--- haskell-hint/trunk/PKGBUILD	                        (rev 0)
+++ haskell-hint/trunk/PKGBUILD	2020-01-08 13:57:02 UTC (rev 550287)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hint
+pkgname=haskell-hint
+pkgver=0.9.0.2
+pkgrel=1
+pkgdesc="Runtime Haskell interpreter (GHC API wrapper)"
+url="https://github.com/haskell-hint/hint"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-exceptions' 'haskell-ghc' 'haskell-ghc-paths' 'haskell-random'
+         'haskell-temporary')
+makedepends=('ghc' 'haskell-extensible-exceptions' 'haskell-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('a2c5391059628bf677be4b179115fbb74e185180d5084bba911fa6b2422d1b3de6ded45ec5b78cefee2ffef6ae75e3810ebc2d5bc0a453d3ae084298bb5ae2ed')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}