[arch-commits] Commit in ruby-sassc/repos (community-x86_64 community-x86_64/PKGBUILD)

[Anatol Pomozov]

    Date: Thursday, January 9, 2020 @ 16:52:00
  Author: anatolik
Revision: 551347

archrelease: copy trunk to community-x86_64

Added:
  ruby-sassc/repos/community-x86_64/
  ruby-sassc/repos/community-x86_64/PKGBUILD
    (from rev 551346, ruby-sassc/trunk/PKGBUILD)

----------+
 PKGBUILD |   29 +++++++++++++++++++++++++++++
 1 file changed, 29 insertions(+)

Copied: ruby-sassc/repos/community-x86_64/PKGBUILD (from rev 551346, ruby-sassc/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-01-09 16:52:00 UTC (rev 551347)
@@ -0,0 +1,29 @@
+# Maintainer: Anatol Pomozov
+
+_gemname=sassc
+pkgname=ruby-$_gemname
+pkgver=2.2.1
+pkgrel=2
+pkgdesc="Use libsass with Ruby!"
+arch=(x86_64)
+url='https://github.com/sass/sassc-ruby'
+license=(MIT)
+depends=(ruby ruby-ffi)
+options=(!emptydirs)
+source=(https://rubygems.org/downloads/$_gemname-$pkgver.gem)
+noextract=($_gemname-$pkgver.gem)
+sha1sums=('b496f902738b776c45bfda4e5331d46ab86f07a6')
+
+package() {
+  local _gemdir=$(gem env gemdir)
+  local _extdir=$(ruby -e'puts File.join(Gem.default_dir, "extensions", Gem::Platform.local.to_s, Gem.extension_api_version)')/$_gemname-$pkgver
+  gem install --ignore-dependencies --no-document --no-user-install -i "$pkgdir/$_gemdir" -n "$pkgdir"/usr/bin $_gemname-$pkgver.gem -- --disable-march-tune-native
+  rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
+  install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+
+  ln -s "/$_extdir/sassc/libsass.so" "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/lib/sassc/"
+
+  # remove junk
+  rm -r "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/"{ext,test}
+  rm "$pkgdir/$_extdir"/gem_make.out
+}