[arch-commits] Commit in libteam/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, January 9, 2020 @ 22:57:10
  Author: heftig
Revision: 373109

archrelease: copy trunk to extra-x86_64

Added:
  libteam/repos/extra-x86_64/PKGBUILD
    (from rev 373108, libteam/trunk/PKGBUILD)
Deleted:
  libteam/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  116 ++++++++++++++++++++++++++++---------------------------------
 1 file changed, 54 insertions(+), 62 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-01-09 22:56:52 UTC (rev 373108)
+++ PKGBUILD	2020-01-09 22:57:10 UTC (rev 373109)
@@ -1,62 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-
-pkgname=libteam
-pkgver=1.29
-pkgrel=4
-pkgdesc="Library for controlling team network device"
-arch=(x86_64)
-url="http://libteam.org/"
-license=(LGPL)
-depends=(libnl libdaemon jansson libdbus bash zeromq)
-makedepends=(python python2 swig git doxygen graphviz)
-_commit=e897f02bf2403d4859a99e090e34ea768b4c0540  # tags/v1.29
-source=("git+https://github.com/jpirko/libteam#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-
-  # Reduce docs size
-  printf '%s\n' >>doc/Doxyfile.in \
-    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
-
-  NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
-  cd $pkgname
-  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
-    --disable-static --libexecdir=/usr/lib
-  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
-  make all html
-
-  cp -aT binding/python binding/python2
-  (cd binding/python;  python  ./setup.py build;)
-  (cd binding/python2; python2 ./setup.py build;)
-}
-
-check() {
-  cd $pkgname
-  make check
-}
-
-package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
-
-  install -Dm644 teamd/redhat/systemd/teamd at .service \
-    "$pkgdir/usr/lib/systemd/system/teamd at .service"
-  install -Dm644 teamd/dbus/teamd.conf \
-    "$pkgdir/usr/share/dbus-1/system.d/teamd.conf"
-
-  (cd binding/python;  python  ./setup.py install --root "$pkgdir" -O1;)
-  (cd binding/python2; python2 ./setup.py install --root "$pkgdir" -O1;)
-
-  mkdir -p "$pkgdir/usr/share/doc/$pkgname"
-  cp -a doc/api "$pkgdir/usr/share/doc/$pkgname"
-}

Copied: libteam/repos/extra-x86_64/PKGBUILD (from rev 373108, libteam/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-01-09 22:57:10 UTC (rev 373109)
@@ -0,0 +1,54 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=libteam
+pkgver=1.30
+pkgrel=1
+pkgdesc="Library for controlling team network device"
+arch=(x86_64)
+url="http://libteam.org/"
+license=(LGPL)
+depends=(libnl libdaemon jansson libdbus bash zeromq)
+makedepends=(python swig git doxygen graphviz)
+_commit=471fb50d206e5a3f2eef9e4247329b51edc5c493  # tags/v1.30
+source=("git+https://github.com/jpirko/libteam#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --disable-static --libexecdir=/usr/lib
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make all html
+
+  cd binding/python
+  python setup.py build
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+
+  install -Dt "$pkgdir/usr/lib/systemd/system" -m644 teamd/redhat/systemd/teamd at .service
+  install -Dt "$pkgdir/usr/share/dbus-1/system.d" -m644 teamd/dbus/teamd.conf
+
+  mkdir -p "$pkgdir/usr/share/doc/$pkgname"
+  cp -a doc/api "$pkgdir/usr/share/doc/$pkgname"
+
+  cd binding/python
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}