[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Sat Jan 11 17:04:44 UTC 2020


    Date: Saturday, January 11, 2020 @ 17:04:44
  Author: felixonmars
Revision: 551955

addpkg: haskell-indexed-profunctors 0.1-1

Added:
  haskell-indexed-profunctors/
  haskell-indexed-profunctors/repos/
  haskell-indexed-profunctors/trunk/
  haskell-indexed-profunctors/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: haskell-indexed-profunctors/trunk/PKGBUILD
===================================================================
--- haskell-indexed-profunctors/trunk/PKGBUILD	                        (rev 0)
+++ haskell-indexed-profunctors/trunk/PKGBUILD	2020-01-11 17:04:44 UTC (rev 551955)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=indexed-profunctors
+pkgname=haskell-indexed-profunctors
+pkgver=0.1
+pkgrel=1
+pkgdesc="Utilities for indexed profunctors"
+url="https://github.com/well-typed/optics"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('93ad039075a37826f4aa3c3592a19bc655c8988f8d02c033f4f05ae8bd683efbe5c287cf992f6a5ca63572a04cab55c7df402cef0955dfe0715d457a15d633a7')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list