[arch-commits] Commit in gnucash/repos (2 files)

Balló György bgyorgy at archlinux.org
Mon Jan 13 10:46:23 UTC 2020


    Date: Monday, January 13, 2020 @ 10:46:22
  Author: bgyorgy
Revision: 552319

archrelease: copy trunk to community-staging-x86_64

Added:
  gnucash/repos/community-staging-x86_64/
  gnucash/repos/community-staging-x86_64/PKGBUILD
    (from rev 552318, gnucash/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gnucash/repos/community-staging-x86_64/PKGBUILD (from rev 552318, gnucash/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-01-13 10:46:22 UTC (rev 552319)
@@ -0,0 +1,49 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: Mark Schneider <queueRAM at gmail.com>
+
+pkgname=gnucash
+pkgver=3.8
+pkgrel=4
+pkgdesc='Personal and small-business financial-accounting application'
+arch=(x86_64)
+url='https://gnucash.org/'
+license=(GPL)
+depends=(aqbanking boost-libs guile libdbi webkit2gtk)
+makedepends=(boost cmake gmock libdbi-drivers mariadb-libs postgresql-libs)
+optdepends=('gnucash-docs: documentation'
+            'libdbi-drivers: open and save data into SQL database'
+            'perl-date-manip: stock information lookups'
+            'perl-finance-quote: stock information lookups')
+options=(!emptydirs)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-${pkgver}b.tar.gz)
+sha256sums=('2a4ff781ec905ebe7e00f16a0a50358268d1bc5ebd7e5f70a50a44bcea5bffaf')
+
+build() {
+  cd $pkgname-$pkgver
+
+  # Do not treat warnings as errors
+  sed -e 's|-Werror||g' -i CMakeLists.txt
+
+  cmake	-DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+        -DWITH_PYTHON=ON \
+        -DHAVE_GWEN_GTK3=ON \
+        -DCOMPILE_GSCHEMAS=OFF
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make -k check || : # 2 tests failed
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # Delete the gnucash-valgrind executable because the source files
+  # are not included with the package and the executable is hardlinked
+  # to the location that it was built at.
+  rm -f "$pkgdir/usr/bin/gnucash-valgrind"
+}



More information about the arch-commits mailing list