[arch-commits] Commit in (4 files)

[David Runge]

    Date: Tuesday, January 14, 2020 @ 16:24:24
  Author: dvzrv
Revision: 552516

Adding guitarix (to replace guitarix2, because the name doesn't make any sense).

Added:
  guitarix/
  guitarix/repos/
  guitarix/trunk/
  guitarix/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: guitarix/trunk/PKGBUILD
===================================================================
--- guitarix/trunk/PKGBUILD	                        (rev 0)
+++ guitarix/trunk/PKGBUILD	2020-01-14 16:24:24 UTC (rev 552516)
@@ -0,0 +1,40 @@
+# Maintainer: David Runge <dvzrv at archlinux.org
+
+pkgname=guitarix
+pkgver=0.39.0
+pkgrel=1
+pkgdesc="A simple mono guitar amplifier and FX for JACK using Faust"
+arch=('x86_64')
+url="https://guitarix.org"
+license=('GPL3')
+groups=('ladspa-plugins' 'lv2-plugins' 'pro-audio')
+depends=('avahi' 'bluez-libs' 'cairo' 'cairomm' 'gcc-libs' 'gdk-pixbuf2'
+'glib2' 'glibc' 'glibmm' 'gtk2' 'gtkmm' 'libboost_iostreams.so' 'libcurl.so'
+'libjack.so' 'liblilv-0.so' 'liblrdf.so' 'libsndfile.so' 'libzita-convolver.so'
+'libzita-resampler.so' 'pango' 'pangomm' 'ttf-roboto')
+makedepends=('boost' 'eigen' 'gperf' 'intltool' 'ladspa' 'lv2' 'waf')
+provides=('libgxw.so' 'libgxwmm.so')
+replaces=('guitarix2')
+source=("${pkgname}-${pkgver}.tar.xz::https://download.sourceforge.net/project/guitarix/guitarix/${pkgname}2-${pkgver}.tar.xz")
+sha512sums=('5eb799498385ab9aa865e3f5a7e79d77f7f62c9bd7ad6875ec32bdec85829ed5b84bed3b0eab786ce74088fe2e1d53080f70afcb25ab1ef8d8f78a676b4947df')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  # when building with faust 2.20.2 it fails: https://sourceforge.net/p/guitarix/bugs/86/
+  waf configure --prefix=/usr \
+                --enable-nls \
+                --ladspa \
+                --new-ladspa \
+                --no-faust \
+                --shared-lib \
+                --lib-dev \
+                --ldflags="${LDFLAGS}"
+  waf build -vv
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  waf install --destdir="${pkgdir}"
+  # docs
+  install -vDm 644 {changelog,README} -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}