[arch-commits] Commit in (4 files)

[David Runge]

    Date: Tuesday, January 14, 2020 @ 23:36:30
  Author: dvzrv
Revision: 552552

Adding python-django-crispy-forms as checkdepends for python-django-filter.

Added:
  python-django-crispy-forms/
  python-django-crispy-forms/repos/
  python-django-crispy-forms/trunk/
  python-django-crispy-forms/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: python-django-crispy-forms/trunk/PKGBUILD
===================================================================
--- python-django-crispy-forms/trunk/PKGBUILD	                        (rev 0)
+++ python-django-crispy-forms/trunk/PKGBUILD	2020-01-14 23:36:30 UTC (rev 552552)
@@ -0,0 +1,41 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=django-crispy-forms
+pkgname=python-django-crispy-forms
+pkgver=1.8.1
+pkgrel=1
+pkgdesc="The best way to have DRY Django forms"
+arch=('any')
+url="https://github.com/django-crispy-forms/django-crispy-forms"
+license=('MIT')
+depends=('python-django')
+makedepends=('python-setuptools')
+checkdepends=('python-coverage' 'python-pytest' 'python-pytest-cov' 'python-pytest-django')
+source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
+sha512sums=('5f6db6cf158b9472a2f8afe8b8bd541b23cbe1aba7e3a7e5b45504ed4ae5e8181345a9288f953937e38bd2a12f71d540b54c43952e04ec6f3c4d079fb7e01934')
+
+prepare() {
+  mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  export PYTHONPATH="build:${PYTHONPATH}"
+  DJANGO_SETTINGS_MODULE=crispy_forms.tests.test_settings pytest -v crispy_forms/tests --cov=crispy_forms
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --prefix=/usr \
+    --root="${pkgdir}"
+  install -vDm 644 {CONTRIBUTORS.txt,README.rst} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}