[arch-commits] Commit in ucblogo/repos/community-x86_64 (6 files)
Alexander Rødseth
arodseth at archlinux.org
Thu Jan 16 13:37:44 UTC 2020
Date: Thursday, January 16, 2020 @ 13:37:44
Author: arodseth
Revision: 552766
archrelease: copy trunk to community-x86_64
Added:
ucblogo/repos/community-x86_64/PKGBUILD
(from rev 552765, ucblogo/trunk/PKGBUILD)
ucblogo/repos/community-x86_64/logo.sh
(from rev 552765, ucblogo/trunk/logo.sh)
Deleted:
ucblogo/repos/community-x86_64/PKGBUILD
ucblogo/repos/community-x86_64/logo.sh
ucblogo/repos/community-x86_64/no-tex.patch
ucblogo/repos/community-x86_64/no-wx.patch
--------------+
PKGBUILD | 128 ++++++++++++++++++++++++++-------------------------------
logo.sh | 14 +++---
no-tex.patch | 12 -----
no-wx.patch | 52 -----------------------
4 files changed, 67 insertions(+), 139 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2020-01-16 13:37:38 UTC (rev 552765)
+++ PKGBUILD 2020-01-16 13:37:44 UTC (rev 552766)
@@ -1,68 +0,0 @@
-# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
-# Contributor: chiku <chirantan.mitra at gmail.com>
-
-pkgname=ucblogo
-pkgver=6.0
-pkgrel=10
-pkgdesc='Interpreter for the Logo programming language'
-url='https://www.cs.berkeley.edu/~bh/logo.html'
-arch=(x86_64)
-license=(GPL)
-makedepends=(setconf svn)
-depends=(libice libsm libx11 ncurses)
-source=("https://www.cs.berkeley.edu/~bh/downloads/$pkgname.tar.gz"
- 'https://people.eecs.berkeley.edu/~bh/logo-sample.html'
- no-wx.patch
- no-tex.patch
- logo.sh)
-sha256sums=('c659e989e9284efc0f904ebd7de24b559c2d7434a98bb9c92c23e6c11b49cef3'
- 'd3dfeb90e5dd6cae6bc12c8b272e1203a2b2693963670a408d2a190d1ba819ab'
- 'e360ac71ac785fa8b00b89ff0c5bf8ed738114013143245d3bc0e62eb7d0333d'
- 'e83fb9d656a9064685cde5ebc0ee36242ac848228380b0567fe683901435707c'
- 'b14dfea1bfc5f04df254e4067d8d6301851d42af6920bdb800fdd8ad4443682b')
-
-prepare() {
- cd $pkgname-$pkgver
-
- # Add missing includes
- for csrc in coms.c graphics.c; do
- sed -i '1s,^,#include <math.h>\n,' "$csrc"
- done
-
- # Various patching
- patch -Np2 -i "$srcdir/no-wx.patch"
- patch -Np2 -i "$srcdir/no-tex.patch"
- sed -i 's/define HAVE_MATHERR 1/undef HAVE_MATHERR/' config.h
- setconf svn.c 'char* SVN' '"(1)";'
-
- # The makefile does not respect CFLAGS, set it manually
- setconf makefile CFLAGS "$CFLAGS -w -fPIC"
-
- # Create an example logo file, to be placed in /usr/share/doc/ucblogo
- echo '#!/usr/bin/env logo' > "$srcdir/sample.logo"
- head -22 < "$srcdir/logo-sample.html" | grep -v '<' >> "$srcdir/sample.logo"
-}
-
-build() {
- make -C $pkgname-$pkgver
- rm -rf $pkgname-$pkgver/csls/CVS
-}
-
-package() {
- make -C $pkgname-$pkgver \
- INFODIR="$pkgdir/usr/share/info" \
- prefix="$pkgdir/usr" \
- install
-
- # Package executable and wrapper script
- mv "$pkgdir/usr/bin/logo" "$pkgdir/usr/bin/logo.elf"
- install -Dm755 logo.sh "$pkgdir/usr/bin/logo"
-
- # Package documentation
- install -d "$pkgdir/usr/share/doc"
- mv "$pkgdir/usr/lib/logo/docs" "$pkgdir/usr/share/doc/$pkgname"
- rm "$pkgdir/usr/share/doc/$pkgname/usermanual.ps"
- install -Dm755 sample.logo "$pkgdir/usr/share/doc/$pkgname/sample.logo"
-}
-
-# vim: ts=2 sw=2 et:
Copied: ucblogo/repos/community-x86_64/PKGBUILD (from rev 552765, ucblogo/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2020-01-16 13:37:44 UTC (rev 552766)
@@ -0,0 +1,60 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: chiku <chirantan.mitra at gmail.com>
+
+pkgname=ucblogo
+pkgver=6.1
+pkgrel=1
+pkgdesc='Interpreter for the Logo programming language'
+url='https://www.cs.berkeley.edu/~bh/logo.html'
+arch=(x86_64)
+license=(GPL)
+makedepends=(setconf svn)
+depends=(libice libsm libx11 ncurses wxgtk3)
+source=("https://www.cs.berkeley.edu/~bh/downloads/$pkgname.tar.gz"
+ 'https://people.eecs.berkeley.edu/~bh/logo-sample.html'
+ logo.sh)
+sha256sums=('f35d8faf2dd8c4347ff67816570b20d935c19e4f6acb5301708ef2b81d9f9339'
+ 'd3dfeb90e5dd6cae6bc12c8b272e1203a2b2693963670a408d2a190d1ba819ab'
+ 'b14dfea1bfc5f04df254e4067d8d6301851d42af6920bdb800fdd8ad4443682b')
+
+prepare() {
+ # Create an example logo file, to be placed in /usr/share/doc/ucblogo
+ echo '#!/usr/bin/env logo' > "$srcdir/sample.logo"
+ head -22 < "$srcdir/logo-sample.html" | grep -v '<' >> "$srcdir/sample.logo"
+}
+
+build() {
+ cd $pkgname-$pkgver
+
+ ./configure --prefix=/usr
+
+ setconf makefile LINKER '$(CXX)'
+
+ # The makefile does not respect CFLAGS, set it manually
+ setconf makefile CFLAGS "$CFLAGS -w -fPIC -pthread"
+ setconf makefile CXXFLAGS "$CXXFLAGS -w -fPIC -D_FILE_OFFSET_BITS=64 -D_LARGE_FILES -pthread"
+
+ make
+
+ # Cleanup
+ rm -rf $pkgname-$pkgver/csls/CVS
+}
+
+package() {
+ make -C $pkgname-$pkgver \
+ INFODIR="$pkgdir/usr/share/info" \
+ prefix="$pkgdir/usr" \
+ install
+
+ # Package executable and wrapper script
+ mv "$pkgdir/usr/bin/logo" "$pkgdir/usr/bin/logo.elf"
+ install -Dm755 logo.sh "$pkgdir/usr/bin/logo"
+
+ # Package documentation
+ install -d "$pkgdir/usr/share/doc"
+ mv "$pkgdir/usr/lib/logo/docs" "$pkgdir/usr/share/doc/$pkgname"
+ rm "$pkgdir/usr/share/doc/$pkgname/usermanual.ps"
+ install -Dm755 sample.logo "$pkgdir/usr/share/doc/$pkgname/sample.logo"
+}
+
+# vim: ts=2 sw=2 et:
Deleted: logo.sh
===================================================================
--- logo.sh 2020-01-16 13:37:38 UTC (rev 552765)
+++ logo.sh 2020-01-16 13:37:44 UTC (rev 552766)
@@ -1,7 +0,0 @@
-#!/bin/sh
-export LOGOLIB=/usr/lib/logo/logolib
-if [[ -f "$1" ]]; then
- /usr/bin/logo.elf "$*" < "$1" | head -n-2
-else
- /usr/bin/logo.elf "$@"
-fi
Copied: ucblogo/repos/community-x86_64/logo.sh (from rev 552765, ucblogo/trunk/logo.sh)
===================================================================
--- logo.sh (rev 0)
+++ logo.sh 2020-01-16 13:37:44 UTC (rev 552766)
@@ -0,0 +1,7 @@
+#!/bin/sh
+export LOGOLIB=/usr/lib/logo/logolib
+if [[ -f "$1" ]]; then
+ /usr/bin/logo.elf "$*" < "$1" | head -n-2
+else
+ /usr/bin/logo.elf "$@"
+fi
Deleted: no-tex.patch
===================================================================
--- no-tex.patch 2020-01-16 13:37:38 UTC (rev 552765)
+++ no-tex.patch 2020-01-16 13:37:44 UTC (rev 552766)
@@ -1,12 +0,0 @@
-diff -ENwbur ucblogo-6.0-no-wxWidgets/docs/makefile ucblogo-6.0-no-texinfo/docs/makefile
---- src/ucblogo-6.0/docs/makefile 2013-03-19 07:18:52.000000000 +0530
-+++ src/ucblogo-6.0-b/docs/makefile 2013-03-21 06:21:03.000000000 +0530
-@@ -30,7 +30,7 @@
- ship:
- -rm -f *.{aux,cp,cps,dvi,fn,ky,log,pg,toc,tp,vr}
-
--install: all
-+install:
- for d in $(INFODIR) $(DOCSDIR) $(HTMLDIR); do [ -d $$d ] || mkdir -p $$d || exit 1; done
- -cp -f *.info* $(INFODIR)/.
- -cp -f html/*.html $(HTMLDIR)/.
Deleted: no-wx.patch
===================================================================
--- no-wx.patch 2020-01-16 13:37:38 UTC (rev 552765)
+++ no-wx.patch 2020-01-16 13:37:44 UTC (rev 552766)
@@ -1,52 +0,0 @@
-diff -ENwbur ucblogo-6.0/config.h ucblogo-6.0-no-wxWidgets/config.h
---- src/ucblogo-6.0/config.h 2007-11-27 00:42:40.000000000 +0530
-+++ src/ucblogo-6.0-b/config.h 2013-03-19 07:19:15.000000000 +0530
-@@ -74,4 +74,4 @@
- /* #undef HAVE_LIBTERMLIB */
-
- /* Define if you have the wx library. */
--#define HAVE_WX 1
-+/* #undef HAVE_WX */
-Binary files ucblogo-6.0/logo and ucblogo-6.0-no-wxWidgets/logo differ
-diff -ENwbur ucblogo-6.0/makefile ucblogo-6.0-no-wxWidgets/makefile
---- src/ucblogo-6.0/makefile 2008-09-14 02:51:18.000000000 +0530
-+++ src/ucblogo-6.0-b/makefile 2013-03-19 07:25:44.000000000 +0530
-@@ -1,23 +1,23 @@
- CC = gcc
--CFLAGS = -g -O -DHAVE_WX -O0
-+CFLAGS = -g -O2
- CXX = g++
--CXXFLAGS = -g -DHAVE_WX -I/usr/local/lib/wx/include/gtk2-ansi-release-static-2.8 -I/usr/local/include/wx-2.8 -D_FILE_OFFSET_BITS=64 -D_LARGE_FILES -D__WXGTK__ -pthread
- LDFLAGS =
--LIBS = -lbsd -lm -L/usr/local/lib -pthread /usr/local/lib/libwx_gtk2_richtext-2.8.a /usr/local/lib/libwx_gtk2_aui-2.8.a /usr/local/lib/libwx_gtk2_xrc-2.8.a /usr/local/lib/libwx_gtk2_qa-2.8.a /usr/local/lib/libwx_gtk2_html-2.8.a /usr/local/lib/libwx_gtk2_adv-2.8.a /usr/local/lib/libwx_gtk2_core-2.8.a /usr/local/lib/libwx_base_xml-2.8.a /usr/local/lib/libwx_base_net-2.8.a /usr/local/lib/libwx_base-2.8.a -pthread -L/lib -lgtk-x11-2.0 -lgdk-x11-2.0 -latk-1.0 -lgdk_pixbuf-2.0 -lpango-1.0 -lgobject-2.0 -lgmodule-2.0 -lgthread-2.0 -lrt -lglib-2.0 -lXinerama -lXxf86vm -lSM -lpng -ljpeg -ltiff -lexpat -lz -ldl -lm -ltermcap -lX11
-+LIBS = -lSM -lICE -lm -lcurses -lX11
- prefix = /usr/local
- BINDIR = $(prefix)/bin
- LIBLOC = $(prefix)/lib/logo
--LINKER = $(CXX)
-+LINKER = $(CC)
-+
-
- # LIBLOC = `pwd`
-
- OBJS = coms.o error.o eval.o files.o graphics.o init.o intern.o \
- libloc.o lists.o logodata.o main.o math.o mem.o paren.o parse.o \
-- print.o wrksp.o nographics.o svn.o wxMain.o wxTerminal.o wxTurtleGraphics.o TextEditor.o wxterm.o
-+ print.o wrksp.o nographics.o svn.o term.o xgraphics.o
-
- SRCS = coms.c error.c eval.c files.c graphics.c init.c intern.c \
- libloc.c lists.c logodata.c main.c math.c mem.c paren.c parse.c \
-- print.c wrksp.c nographics.c wxMain.cpp wxTerminal.cpp wxTurtleGraphics.cpp TextEditor.cpp wxterm.c
-+ print.c wrksp.c nographics.c term.c xgraphics.c
-
- HDRS = globals.h logo.h xgraphics.h
-
-@@ -70,7 +70,7 @@
- # cd emacs; $(MAKE) ship
- cd docs; $(MAKE) ship
-
--install: all
-+install:
- for d in $(BINDIR) $(LIBLOC) $(LIBLOC)/logolib $(LIBLOC)/helpfiles $(LIBLOC)/csls; do [ -d $$d ] || mkdir -p $$d || exit 1; done
- cp logo $(BINDIR)/.
- cp -f logolib/* $(LIBLOC)/logolib/.
More information about the arch-commits
mailing list