[arch-commits] Commit in mpv/repos (2 files)

[Levente Polyak]

    Date: Friday, January 17, 2020 @ 23:07:01
  Author: anthraxx
Revision: 552920

archrelease: copy trunk to community-staging-x86_64

Added:
  mpv/repos/community-staging-x86_64/
  mpv/repos/community-staging-x86_64/PKGBUILD
    (from rev 552919, mpv/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: mpv/repos/community-staging-x86_64/PKGBUILD (from rev 552919, mpv/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-01-17 23:07:01 UTC (rev 552920)
@@ -0,0 +1,54 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Eivind Uggedal <eivind at uggedal.com>
+
+pkgname=mpv
+epoch=1
+pkgver=0.31.0
+pkgrel=2
+pkgdesc='a free, open source, and cross-platform media player'
+arch=('x86_64')
+# We link against libraries that are licensed GPLv3 explicitly, libsmbclient
+# being one of these. So our package is GPLv3 only as well.
+license=('GPL3')
+url='https://mpv.io/'
+depends=('desktop-file-utils' 'ffmpeg' 'hicolor-icon-theme' 'libjack.so' 'lcms2'
+         'libarchive' 'libcaca' 'libcdio-paranoia' 'libdvdnav' 'libgl' 'libva'
+         'libxinerama' 'libxkbcommon' 'libxrandr' 'libxss' 'libxv' 'lua52'
+         'librubberband.so' 'smbclient' 'uchardet' 'vulkan-icd-loader' 'wayland'
+         'xdg-utils' 'shaderc' 'mujs' 'libplacebo' 'libplacebo.so')
+makedepends=('mesa' 'python-docutils' 'ladspa' 'wayland-protocols'
+             'ffnvcodec-headers' 'vulkan-headers' 'waf')
+optdepends=('youtube-dl: for video-sharing websites playback')
+provides=('libmpv.so')
+options=('!emptydirs')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/mpv-player/$pkgname/archive/v$pkgver.tar.gz")
+sha256sums=('805a3ac8cf51bfdea6087a6480c18835101da0355c8e469b6d488a1e290585a5')
+
+build() {
+  cd ${pkgname}-${pkgver}
+
+  waf configure --prefix=/usr \
+    --confdir=/etc/mpv \
+    --enable-cdda \
+    --enable-dvb \
+    --enable-dvdnav \
+    --enable-libarchive \
+    --enable-libmpv-shared \
+    --enable-libsmbclient \
+    --disable-build-date
+
+  waf build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+
+  waf install --destdir="$pkgdir"
+
+  install -m0644 DOCS/{encoding.rst,tech-overview.txt} \
+    "$pkgdir"/usr/share/doc/mpv
+
+  install -m0644 TOOLS/lua/* \
+    -D -t "$pkgdir"/usr/share/mpv/scripts
+}