[arch-commits] Commit in gsignond (3 files)
Maxime Gauduin
alucryd at archlinux.org
Sun Jan 19 11:55:29 UTC 2020
Date: Sunday, January 19, 2020 @ 11:55:28
Author: alucryd
Revision: 553141
archrelease: copy trunk to community-x86_64
Added:
gsignond/repos/
gsignond/repos/community-x86_64/
gsignond/repos/community-x86_64/PKGBUILD
(from rev 553140, gsignond/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: gsignond/repos/community-x86_64/PKGBUILD (from rev 553140, gsignond/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD (rev 0)
+++ repos/community-x86_64/PKGBUILD 2020-01-19 11:55:28 UTC (rev 553141)
@@ -0,0 +1,50 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail.com>
+
+pkgname=gsignond
+pkgver=1.2.0
+pkgrel=2
+pkgdesc='gSSO glib daemon'
+arch=(x86_64)
+url=https://01.org/gsso
+license=(LGPL2.1)
+depends=(
+ glib2
+ glibc
+ sqlite
+)
+makedepends=(
+ git
+ gobject-introspection
+ meson
+ vala
+)
+provides=(libgsignond-common.so)
+backup=(etc/gsignond.conf)
+source=(git+https://gitlab.com/accounts-sso/gsignond.git#tag=254b810114e70be4adff4aed30697c650641c2d9)
+sha256sums=(SKIP)
+
+pkgver() {
+ cd gsignond
+
+ git describe --tags
+}
+
+prepare() {
+ cd gsignond
+
+ git cherry-pick -n 39022c86ddb5062a10fb0503ad9d81a8e532d527
+}
+
+build() {
+ arch-meson gsignond build \
+ -D documentation=false
+ ninja -C build
+}
+
+package() {
+ DESTDIR="${pkgdir}" ninja -C build install
+ find "${pkgdir}" -type f -name com.google.code.AccountsSSO.SingleSignOn.* -delete
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list