[arch-commits] Commit in dolphin-emu/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Maxime Gauduin]

    Date: Thursday, January 23, 2020 @ 13:28:14
  Author: alucryd
Revision: 554950

archrelease: copy trunk to community-x86_64

Added:
  dolphin-emu/repos/community-x86_64/PKGBUILD
    (from rev 554949, dolphin-emu/trunk/PKGBUILD)
Deleted:
  dolphin-emu/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  130 +++++++++++++++++++++++++++++++++----------------------------
 1 file changed, 72 insertions(+), 58 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-01-23 13:28:09 UTC (rev 554949)
+++ PKGBUILD	2020-01-23 13:28:14 UTC (rev 554950)
@@ -1,58 +0,0 @@
-# Maintainer: schuay <jakob.gruber at gmail.com>
-# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
-# Contributor: Jeremy Newton (Mystro256) <alexjnewt at gmail.com>
-
-pkgname=dolphin-emu
-pkgver=5.0.r7309.10d230a512
-pkgrel=6
-epoch=1
-pkgdesc='A Gamecube / Wii / Triforce emulator'
-arch=('x86_64')
-url='http://dolphin-emu.org'
-license=('GPL')
-depends=('alsa-lib' 'bluez-libs' 'enet' 'gcc-libs' 'glibc' 'hidapi' 'libevdev'
-         'libgl' 'libpng' 'libpulse' 'libx11' 'libxi' 'libxrandr' 'lzo'
-         'mbedtls' 'qt5-base' 'sfml' 'zlib'
-         'libavcodec.so' 'libavformat.so' 'libavutil.so' 'libcurl.so'
-         'libminiupnpc.so' 'libswscale.so' 'libudev.so' 'libusb-1.0.so')
-makedepends=('cmake' 'git')
-optdepends=('pulseaudio: PulseAudio backend')
-options=('!emptydirs')
-_commit='10d230a512b99aee66f7343481ed13d83557de22'
-source=("dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=${_commit}")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd dolphin-emu
-
-  git describe | sed 's/-/.r/; s/-g/./'
-}
-
-prepare() {
-  if [[ -d build ]]; then
-    rm -rf build
-  fi
-  mkdir build
-}
-
-build() {
-  cd build
-
-  cmake ../dolphin-emu \
-    -DCMAKE_INSTALL_PREFIX='/usr' \
-    -DENABLE_QT2='ON' \
-    -DENABLE_WX='OFF' \
-    -DUSE_SHARED_ENET='ON' \
-    -DDISTRIBUTOR='archlinux.org'
-  make
-}
-
-package() {
-  cd build
-
-  make DESTDIR="${pkgdir}" install
-
-  install -Dm 644 ../dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
-}
-
-# vim: ts=2 sw=2 et:

Copied: dolphin-emu/repos/community-x86_64/PKGBUILD (from rev 554949, dolphin-emu/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-01-23 13:28:14 UTC (rev 554950)
@@ -0,0 +1,72 @@
+# Maintainer: schuay <jakob.gruber at gmail.com>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Jeremy Newton (Mystro256) <alexjnewt at gmail.com>
+
+pkgname=dolphin-emu
+pkgver=5.0.r11530.ea9b96370d
+pkgrel=1
+epoch=1
+pkgdesc='A Gamecube / Wii / Triforce emulator'
+arch=(x86_64)
+url=https://dolphin-emu.org
+license=(GPL)
+depends=(
+  alsa-lib
+  bluez-libs
+  enet
+  gcc-libs
+  glibc
+  hidapi
+  libavcodec.so
+  libavformat.so
+  libavutil.so
+  libcurl.so
+  libevdev
+  libgl
+  libminiupnpc.so
+  libpng
+  libpulse
+  libswscale.so
+  libudev.so
+  libusb-1.0.so
+  libx11
+  libxi
+  libxrandr
+  lzo
+  mbedtls
+  pugixml
+  qt5-base
+  sfml
+  zlib
+)
+makedepends=(
+  cmake
+  git
+  python
+)
+optdepends=('pulseaudio: PulseAudio backend')
+options=(!emptydirs)
+source=(dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=ea9b96370df89b446ed25fca5452f0eef33682a9)
+sha256sums=(SKIP)
+
+pkgver() {
+  cd dolphin-emu
+
+  git describe | sed 's/-/.r/; s/-g/./'
+}
+
+build() {
+  cmake -S dolphin-emu -B build \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DUSE_SHARED_ENET=ON \
+    -DDISTRIBUTOR=archlinux.org
+  make -C build
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C build install
+  install -Dm 644 dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
+}
+
+# vim: ts=2 sw=2 et: