[arch-commits] Commit in darktable/repos (2 files)

[Antonio Rojas]

    Date: Monday, January 27, 2020 @ 14:27:58
  Author: arojas
Revision: 556058

archrelease: copy trunk to community-staging-x86_64

Added:
  darktable/repos/community-staging-x86_64/
  darktable/repos/community-staging-x86_64/PKGBUILD
    (from rev 556057, darktable/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: darktable/repos/community-staging-x86_64/PKGBUILD (from rev 556057, darktable/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-01-27 14:27:58 UTC (rev 556058)
@@ -0,0 +1,55 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Christian Himpel <chressie at gmail dot com>
+# Contributor: Johannes Hanika <hanatos at gmail dot com>
+
+pkgname=darktable
+epoch=2
+pkgver=3.0.0
+pkgrel=2
+pkgdesc="Utility to organize and develop raw images"
+arch=(x86_64)
+url="https://darktable.org"
+license=(GPL3)
+depends=(pugixml libjpeg-turbo colord-gtk libgphoto2 openexr lensfun iso-codes zlib
+         exiv2 flickcurl openjpeg2 graphicsmagick lua osm-gps-map libsecret openmp)
+optdepends=('dcraw: base curve script'
+            'perl-image-exiftool: base curve script'
+            'imagemagick: base curve and noise profile scripts'
+            'ghostscript: noise profile script'
+            'gnuplot: noise profile script')
+makedepends=(cmake intltool desktop-file-utils llvm clang python-jsonschema libwebp)
+source=("https://github.com/darktable-org/darktable/releases/download/release-${pkgver}/darktable-${pkgver/rc/.rc}.tar.xz"{,.asc})
+sha256sums=('7195a5ff7ee95ab7c5a57e4e84f8c90cc4728b2c917359203c21293ab754c0db'
+            'SKIP')
+validpgpkeys=(C4CBC150699956E2A3268EF5BB5CC8295B1779C9  # darktable releases <release at darktable.org>
+              F10F9686652B0E949FCD94C318DCA123F949BD3B) # Pascal Obry <pascal at obry.net>
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+    cmake ../${pkgname}-${pkgver/rc/~rc} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+        -DCMAKE_INSTALL_LIBEXECDIR=/usr/lib \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DBINARY_PACKAGE_BUILD=1 \
+        -DBUILD_USERMANUAL=False \
+        -DUSE_LIBSECRET=ON \
+        -DUSE_LUA=ON \
+        -DUSE_COLORD=ON \
+        -DBUILD_CURVE_TOOLS=ON \
+        -DBUILD_NOISE_TOOLS=ON \
+        -DRAWSPEED_ENABLE_LTO=ON \
+        -DPROJECT_VERSION=${pkgver}
+    make
+}
+
+package() {
+    cd build
+    make DESTDIR="${pkgdir}" install
+    ln -s darktable/libdarktable.so "${pkgdir}"/usr/lib/libdarktable.so
+}