[arch-commits] Commit in libsecret/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Tuesday, January 28, 2020 @ 19:32:30
  Author: heftig
Revision: 374222

archrelease: copy trunk to testing-x86_64

Added:
  libsecret/repos/testing-x86_64/
  libsecret/repos/testing-x86_64/PKGBUILD
    (from rev 374221, libsecret/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: libsecret/repos/testing-x86_64/PKGBUILD (from rev 374221, libsecret/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-01-28 19:32:30 UTC (rev 374222)
@@ -0,0 +1,43 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=libsecret
+pkgver=0.20.1
+pkgrel=1
+pkgdesc="Library for storing and retrieving passwords and other secrets"
+url="https://wiki.gnome.org/Projects/Libsecret"
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 libgcrypt)
+checkdepends=(python-dbus dbus-glib python-gobject gjs)
+makedepends=(docbook-xsl gobject-introspection vala git gtk-doc meson valgrind)
+optdepends=('org.freedesktop.secrets: secret storage backend')
+_commit=e4428dd29fb41672a2dff330a600ed7af2dc74de  # tags/0.20.1^0
+source=("git+https://gitlab.gnome.org/GNOME/libsecret.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Install docs
+  git cherry-pick -n 2e85b13f8f3512f9cef0bed7cf8b6734af06bc9b
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  dbus-run-session meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: