[arch-commits] Commit in haskell-blaze-markup/repos (2 files)

Felix Yan felixonmars at archlinux.org
Wed Jan 29 10:40:11 UTC 2020


    Date: Wednesday, January 29, 2020 @ 10:40:11
  Author: felixonmars
Revision: 558598

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-blaze-markup/repos/community-staging-x86_64/
  haskell-blaze-markup/repos/community-staging-x86_64/PKGBUILD
    (from rev 558597, haskell-blaze-markup/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: haskell-blaze-markup/repos/community-staging-x86_64/PKGBUILD (from rev 558597, haskell-blaze-markup/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-01-29 10:40:11 UTC (rev 558598)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=blaze-markup
+pkgname=haskell-blaze-markup
+pkgver=0.8.2.3
+pkgrel=10
+pkgdesc="A blazingly fast markup combinator library for Haskell"
+url="https://jaspervdj.be/blaze"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('592106b5e68be4755bc14ce57fc3bb5b5e009dda2ca36ccf19bef319b30198e91d4d1bb0f987c6c6bcbcfad83bd549b1bd87dc14fba9419711a0e5718157259c')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list