[arch-commits] Commit in sdl2/repos (community-x86_64 community-x86_64/PKGBUILD)

[Sven-Hendrik Haase]

    Date: Thursday, July 2, 2020 @ 23:04:22
  Author: svenstaro
Revision: 390443

archrelease: copy trunk to community-x86_64

Added:
  sdl2/repos/community-x86_64/
  sdl2/repos/community-x86_64/PKGBUILD
    (from rev 390442, sdl2/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: sdl2/repos/community-x86_64/PKGBUILD (from rev 390442, sdl2/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-07-02 23:04:22 UTC (rev 390443)
@@ -0,0 +1,56 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+
+pkgname=sdl2
+pkgver=2.0.12
+pkgrel=2
+pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)"
+arch=('x86_64')
+url="https://www.libsdl.org"
+license=('MIT')
+depends=('glibc' 'libxext' 'libxrender' 'libx11' 'libgl' 'libxcursor' 'libibus' 'hidapi')
+makedepends=('alsa-lib' 'mesa' 'libpulse' 'libxrandr' 'libxinerama' 'wayland' 'libxkbcommon'
+             'wayland-protocols' 'ibus' 'fcitx' 'libxss' 'cmake' 'jack' 'ninja')
+optdepends=('alsa-lib: ALSA audio driver'
+            'libpulse: PulseAudio audio driver'
+            'jack: JACK audio driver')
+source=("https://www.libsdl.org/release/SDL2-${pkgver}.tar.gz"{,.sig})
+sha512sums=('3f1f04af0f3d9dda9c84a2e9274ae8d83ea0da3fc367970a820036cc4dc1dbf990cfc37e4975ae05f0b45a4ffa739c6c19e470c00bf3f2bce9b8b63717b8b317'
+            'SKIP')
+validpgpkeys=('1528635D8053A57F77D1E08630A59377A7763BE6') # Sam Lantinga
+
+prepare() {
+  cd SDL2-${pkgver}
+  sed -i "s/LIBUSB libusb/LIBUSB libusb-1.0/g" cmake/sdlchecks.cmake
+}
+
+build() {
+  cd SDL2-${pkgver}
+  cmake . \
+      -Bbuild \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DSDL_STATIC=OFF \
+      -DSDL_DLOPEN=ON \
+      -DARTS=OFF \
+      -DESD=OFF \
+      -DNAS=OFF \
+      -DALSA=ON \
+      -DHIDAPI=ON \
+      -DPULSEAUDIO_SHARED=ON \
+      -DVIDEO_WAYLAND=ON \
+      -DRPATH=OFF \
+      -DCLOCK_GETTIME=ON \
+      -DJACK_SHARED=ON
+  ninja -C build
+}
+
+package() {
+  cd SDL2-${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+
+  sed -i "s/libSDL2\.a/libSDL2main.a/g" "$pkgdir"/usr/lib/cmake/SDL2/SDL2Targets-noconfig.cmake
+
+  install -Dm644 COPYING.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: