[arch-commits] Commit in wxsvg (3 files)

[Balló György]

    Date: Friday, July 3, 2020 @ 22:13:41
  Author: bgyorgy
Revision: 657669

archrelease: copy trunk to community-x86_64

Added:
  wxsvg/repos/
  wxsvg/repos/community-x86_64/
  wxsvg/repos/community-x86_64/PKGBUILD
    (from rev 657668, wxsvg/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: wxsvg/repos/community-x86_64/PKGBUILD (from rev 657668, wxsvg/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2020-07-03 22:13:41 UTC (rev 657669)
@@ -0,0 +1,37 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Leonidas Spyropoulos <artafinde at gmail com>
+# Contributor: Miguel Revilla <yo at miguelrevilla.com>
+# Contributor: Joshua Stiefer <facedelajunk at gmail.com>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=wxsvg
+pkgver=1.5.22
+pkgrel=2
+pkgdesc="C++ library to create, manipulate and render SVG files"
+arch=(x86_64)
+url="http://wxsvg.sourceforge.net/"
+license=('custom:wxWindows')
+depends=(ffmpeg libexif wxgtk3)
+makedepends=(webkit2gtk)
+source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2")
+sha256sums=('0de168cd9f0ccd309b8640c1b6e89f2a906983bc12efe75b0c5cd30f1eaff529')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -i 's/libwxsvg_la_LDFLAGS = /libwxsvg_la_LDFLAGS = $(LDFLAGS) /' src/Makefile.am
+  autoreconf -fi
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --with-wx-config=/usr/bin/wx-config-gtk3
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}