[arch-commits] Commit in rsync/repos (3 files)

[Christian Hesse]

    Date: Sunday, July 5, 2020 @ 19:06:07
  Author: eworm
Revision: 390889

archrelease: copy trunk to testing-x86_64

Added:
  rsync/repos/testing-x86_64/
  rsync/repos/testing-x86_64/PKGBUILD
    (from rev 390888, rsync/trunk/PKGBUILD)
  rsync/repos/testing-x86_64/rsyncd.conf
    (from rev 390888, rsync/trunk/rsyncd.conf)

-------------+
 PKGBUILD    |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 rsyncd.conf |   10 ++++++++++
 2 files changed, 59 insertions(+)

Copied: rsync/repos/testing-x86_64/PKGBUILD (from rev 390888, rsync/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-07-05 19:06:07 UTC (rev 390889)
@@ -0,0 +1,49 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+
+pkgname=rsync
+_tag='3c97e8e4e4c98a15e71146808692a6215bb6af1c' # git rev-parse v${pkgver}
+pkgver=3.2.2
+pkgrel=1
+pkgdesc='A fast and versatile file copying tool for remote and local files'
+arch=('x86_64')
+url='https://rsync.samba.org/'
+license=('GPL3')
+depends=('acl' 'libacl.so' 'lz4' 'openssl' 'perl' 'popt' 'xxhash' 'libxxhash.so'
+         'zlib' 'zstd')
+makedepends=('git' 'python-commonmark')
+backup=('etc/rsyncd.conf'
+        'etc/xinetd.d/rsync')
+validpgpkeys=('0048C8B026D4C96F0E589C2F6C859FB14B96A8C5') # Wayne Davison <wayned at users.sourceforge.net>
+source=("git+https://github.com/WayneD/rsync#tag=${_tag}?signed"
+        'rsyncd.conf')
+sha256sums=('SKIP'
+            '733ccb571721433c3a6262c58b658253ca6553bec79c2bdd0011810bb4f2156b')
+
+build() {
+	cd "$srcdir/rsync"
+
+	./configure \
+		--prefix=/usr \
+		--disable-debug \
+		--with-included-popt=no \
+		--with-included-zlib=no
+	make
+}
+
+check() {
+	cd "$srcdir/rsync"
+
+	make test
+}
+
+package() {
+	cd "$srcdir/rsync"
+
+	make DESTDIR="$pkgdir" install
+	install -Dm0644 ../rsyncd.conf "$pkgdir/etc/rsyncd.conf"
+	install -Dm0644 packaging/lsb/rsync.xinetd "$pkgdir/etc/xinetd.d/rsync"
+	install -Dm0644 packaging/systemd/rsync.service "$pkgdir/usr/lib/systemd/system/rsyncd.service"
+	install -Dm0644 packaging/systemd/rsync.socket "$pkgdir/usr/lib/systemd/system/rsyncd.socket"
+	install -Dm0644 packaging/systemd/rsync at .service "$pkgdir/usr/lib/systemd/system/rsyncd at .service"
+	install -Dm0755 support/rrsync "$pkgdir/usr/lib/rsync/rrsync"
+}

Copied: rsync/repos/testing-x86_64/rsyncd.conf (from rev 390888, rsync/trunk/rsyncd.conf)
===================================================================
--- testing-x86_64/rsyncd.conf	                        (rev 0)
+++ testing-x86_64/rsyncd.conf	2020-07-05 19:06:07 UTC (rev 390889)
@@ -0,0 +1,10 @@
+uid = nobody
+gid = nobody
+use chroot = no
+max connections = 4
+syslog facility = local5
+pid file = /run/rsyncd.pid
+
+[ftp]
+        path = /srv/ftp
+        comment = ftp area