[arch-commits] Commit in (flowblade flowblade/trunk flowblade/trunk/PKGBUILD)

[Balló György]

    Date: Monday, July 6, 2020 @ 00:09:53
  Author: bgyorgy
Revision: 657943

Move flowblade from AUR with 98 votes

Added:
  flowblade/
  flowblade/trunk/
  flowblade/trunk/PKGBUILD

----------+
 PKGBUILD |   32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)

Added: flowblade/trunk/PKGBUILD
===================================================================
--- flowblade/trunk/PKGBUILD	                        (rev 0)
+++ flowblade/trunk/PKGBUILD	2020-07-06 00:09:53 UTC (rev 657943)
@@ -0,0 +1,32 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: sxe <sxxe at gmx.de>
+
+pkgname=flowblade
+pkgver=2.6
+pkgrel=1
+pkgdesc="Multitrack non-linear video editor"
+arch=(any)
+url="https://jliljebl.github.io/flowblade/"
+license=(GPL3)
+depends=(ffmpeg frei0r-plugins gmic gtk3 mlt python-cairo python-dbus python-gobject
+         python-numpy python-pillow sdl_image swh-plugins)
+source=("https://github.com/jliljebl/$pkgname/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('1caef13b0a21cd0720a4ae9bb8eec414706fd5a5c8562dbb6bb70164cbdfc141')
+
+prepare() {
+  cd $pkgname-$pkgver/$pkgname-trunk
+  _python_site_packages=`echo /usr/lib/python3*/site-packages`
+  sed -i "s|/usr/share/pyshared/Flowblade|$_python_site_packages/Flowblade|" flowblade
+  sed -i "s|,'res/help/\*'|,'res/help/*','res/help/*/*'|
+          s|share/appdata|share/metainfo|" setup.py
+}
+
+build() {
+  cd $pkgname-$pkgver/$pkgname-trunk
+  python3 setup.py build
+}
+
+package() {
+  cd $pkgname-$pkgver/$pkgname-trunk
+  python3 setup.py install --root="$pkgdir" --optimize=1
+}