[arch-commits] Commit in lib32-libpng/repos (2 files)

Christian Hesse eworm at archlinux.org
Mon Jul 6 21:27:21 UTC 2020


    Date: Monday, July 6, 2020 @ 21:27:20
  Author: eworm
Revision: 658069

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libpng/repos/multilib-testing-x86_64/
  lib32-libpng/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 658068, lib32-libpng/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: lib32-libpng/repos/multilib-testing-x86_64/PKGBUILD (from rev 658068, lib32-libpng/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2020-07-06 21:27:20 UTC (rev 658069)
@@ -0,0 +1,47 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+# Contributor: Travis Willard <travis at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+_pkgbasename=libpng
+pkgname=lib32-$_pkgbasename
+pkgver=1.6.37
+_libversion=16
+pkgrel=3
+pkgdesc="A collection of routines used to create PNG format graphics files (32-bit)"
+arch=('x86_64')
+url="http://www.libpng.org/pub/png/libpng.html"
+license=('custom')
+depends=('lib32-zlib' $_pkgbasename)
+makedepends=(gcc-multilib)
+source=("https://downloads.sourceforge.net/sourceforge/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.xz")
+sha256sums=('505e70834d35383537b6491e7ae8641f1a4bed1876dbfe361201fc80868d88ca')
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  ./configure \
+    --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --program-suffix=-32 \
+    --disable-static
+  make
+}
+
+package() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install
+
+  rm -rf "${pkgdir}"/usr/{include,share}
+
+  rm "$pkgdir/usr/bin/libpng-config"
+  ln -s "libpng${_libversion}-config-32" "$pkgdir/usr/bin/libpng-config-32"
+
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}


More information about the arch-commits mailing list