[arch-commits] Commit in ambdec/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 12:32:22
  Author: felixonmars
Revision: 658148

archrelease: copy trunk to community-staging-x86_64

Added:
  ambdec/repos/community-staging-x86_64/
  ambdec/repos/community-staging-x86_64/PKGBUILD
    (from rev 658147, ambdec/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: ambdec/repos/community-staging-x86_64/PKGBUILD (from rev 658147, ambdec/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 12:32:22 UTC (rev 658148)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+pkgname=ambdec
+pkgver=0.7.1
+pkgrel=2
+pkgdesc="An Ambisonic decoder for first and second order"
+arch=('x86_64')
+url="https://kokkinizita.linuxaudio.org/linuxaudio/downloads/index.html"
+license=('GPL2')
+groups=('pro-audio')
+depends=('clxclient' 'clthreads' 'jack')
+makedepends=('gendesk')
+source=("https://kokkinizita.linuxaudio.org/linuxaudio/downloads/${pkgname}-${pkgver}.tar.bz2")
+sha512sums=('26f945e07a5e3e3a2000f00eede2499fd6a6ba82587a84d1bbd344ac3c6c8b86d74773491c9366d79b3697c926950308b5f8593ad14316eced7155d48c1ace0e')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  # strip march=native
+  sed -e '/native/d' \
+      -i source/Makefile
+  # XDG desktop file
+  gendesk -n \
+          --pkgname "${pkgname}" \
+          --name "${pkgname}" \
+          --pkgdesc "${pkgdesc}" \
+          --genericname "Ambisonics Audio Renderer" \
+          --categories "AudioVideo;Audio"
+}
+
+build() {
+  cd "$pkgname-$pkgver/source"
+  make PREFIX=/usr
+}
+
+package() {
+  cd "$pkgname-$pkgver/source"
+  make PREFIX=/usr DESTDIR="$pkgdir/" install
+  install -vDm 644 ../{AUTHORS,README} -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  install -vDm 644 ../presets/*.ambdec \
+    -t "${pkgdir}/usr/share/${pkgname}/presets/"
+  install -vDm 644 ../share/*.png \
+    -t "${pkgdir}/usr/share/${pkgname}/"
+  install -vDm 644 "../${pkgname}.desktop" \
+    -t "${pkgdir}/usr/share/applications/"
+}