[arch-commits] Commit in gambit-c/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Jul 7 13:13:34 UTC 2020


    Date: Tuesday, July 7, 2020 @ 13:13:34
  Author: felixonmars
Revision: 658377

archrelease: copy trunk to community-staging-x86_64

Added:
  gambit-c/repos/community-staging-x86_64/
  gambit-c/repos/community-staging-x86_64/PKGBUILD
    (from rev 658376, gambit-c/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: gambit-c/repos/community-staging-x86_64/PKGBUILD (from rev 658376, gambit-c/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 13:13:34 UTC (rev 658377)
@@ -0,0 +1,38 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Christian Babeux <christian.babeux at 0x80.ca>
+
+pkgname=gambit-c
+pkgver=4.9.3
+pkgrel=2
+pkgdesc='Efficient implementation of the Scheme programming language'
+arch=(x86_64)
+url='https://github.com/gambit/gambit'
+license=(LGPL Apache)
+options=(staticlibs)
+makedepends=(git)
+source=("$pkgname-$pkgver.tgz::https://www.iro.umontreal.ca/~${pkgname%-c}/download/${pkgname%-c}/v${pkgver%.*}/source/${pkgname/-c/-v}${pkgver//./_}-devel.tgz")
+sha256sums=('4321ea0042f349eef673d2607a39c24f72e223aaf63f60298fffb7365f60fe53')
+
+build() {
+  cd "${pkgname/-c/-v}${pkgver//./_}-devel"
+
+  ./configure \
+    --prefix=/usr \
+    --docdir=/usr/share/doc/gambit-c \
+    --infodir=/usr/share/info \
+    --libdir=/usr/lib/gambit-c \
+    --enable-gcc-opts \
+    --enable-single-host
+  make
+}
+
+package() {
+  make -C "${pkgname/-c/-v}${pkgver//./_}-devel" install DESTDIR="$pkgdir"
+
+  # /usr/bin/gsc conflicts with ghostscript
+  mv "$pkgdir/usr/bin/gsc" "$pkgdir/usr/bin/gambitc"
+  ln -sf /usr/bin/gambitc "$pkgdir/usr/bin/gsc-script"
+}
+
+# getver: github.com/gambit/gambit/releases/latest
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list