[arch-commits] Commit in libgig/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 14:07:11
  Author: felixonmars
Revision: 658709

archrelease: copy trunk to community-staging-x86_64

Added:
  libgig/repos/community-staging-x86_64/
  libgig/repos/community-staging-x86_64/PKGBUILD
    (from rev 658708, libgig/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: libgig/repos/community-staging-x86_64/PKGBUILD (from rev 658708, libgig/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 14:07:11 UTC (rev 658709)
@@ -0,0 +1,40 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: svoufff <svoufff at gmail dot com>
+# Contributor: Shinlun Hsieh <yngwiexx at yahoo.com.tw>
+
+pkgname=libgig
+pkgver=4.2.0
+pkgrel=3
+pkgdesc="C++ library for loading, modifying and creating .gig, .ksf, .kmp, .sf2 and DLS files"
+arch=('x86_64')
+url="https://www.linuxsampler.org/libgig/"
+license=('GPL2')
+depends=('util-linux' 'libsndfile')
+provides=('libgig.so')
+source=("https://download.linuxsampler.org/packages/${pkgname}-${pkgver}.tar.bz2")
+sha512sums=('52c8c749c7852e229c76c17211398dbf5dd5891a1ee9d8e8bc61d55b825c5676595b20b26014e739b9bfd387db36895152b380519609a928a8fa68f4a20279f6')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  autoreconf -vfi
+  # creating a ld.so.conf entry for libgig.so
+  echo "/usr/lib/${pkgname}" > "${pkgname}.conf"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  install -vDm 644 {AUTHORS,ChangeLog,NEWS,README,TODO} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  # adding libgig.so library path to ld.so.conf (required for dependants during
+  # runtime)
+  install -vDm 644 "${pkgname}.conf" -t "${pkgdir}/etc/ld.so.conf.d/"
+}
+# vim:set ts=2 sw=2 et: