[arch-commits] Commit in task/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 15:24:38
  Author: felixonmars
Revision: 658911

archrelease: copy trunk to community-staging-x86_64

Added:
  task/repos/community-staging-x86_64/
  task/repos/community-staging-x86_64/PKGBUILD
    (from rev 658909, task/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: task/repos/community-staging-x86_64/PKGBUILD (from rev 658909, task/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 15:24:38 UTC (rev 658911)
@@ -0,0 +1,43 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Peter Lewis <plewis at aur.archlinux.org>
+# Contributor: TDY <tdy at gmx.com>
+# Contributor: Ray Kohler <ataraxia at gmail.com>
+# Contributor: muflax <muflax at gmail.com>
+# Contributor: coolkehon <coolkehon at gmail.com>
+
+pkgname=task
+pkgver=2.5.1
+pkgrel=3
+pkgdesc="A command-line todo list manager"
+arch=('x86_64')
+url="https://taskwarrior.org/"
+license=('MIT')
+depends=('util-linux' 'gnutls')
+makedepends=('cmake')
+optdepends=('bash-completion: for bash completion' 'python: for python export addon' 'ruby: for ruby export addon' 'perl: for perl export addon' 'perl-json: for perl export addon')
+source=("https://taskwarrior.org/download/$pkgname-$pkgver.tar.gz")
+sha256sums=('d87bcee58106eb8a79b850e9abc153d98b79e00d50eade0d63917154984f2a15')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  cmake -DCMAKE_INSTALL_PREFIX=/usr .
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  # Note that we rename the bash completion script for bash-completion > 1.99, until upstream does so.
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/bash/task.sh" "$pkgdir/usr/share/bash-completion/completions/task"
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/fish/task.fish" "$pkgdir/usr/share/fish/vendor_completions.d/task.fish"
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/zsh/_task" "$pkgdir/usr/share/zsh/site-functions/_task"
+
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/ftdetect/task.vim" "$pkgdir/usr/share/vim/vimfiles/ftdetect/task.vim"
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/syntax/taskdata.vim" "$pkgdir/usr/share/vim/vimfiles/syntax/taskdata.vim"
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/syntax/taskedit.vim" "$pkgdir/usr/share/vim/vimfiles/syntax/taskedit.vim"
+  install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/syntax/taskrc.vim" "$pkgdir/usr/share/vim/vimfiles/syntax/taskrc.vim"
+
+  install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/task/LICENSE"
+}