[arch-commits] Commit in libantlr3c/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Jul 7 15:54:05 UTC 2020


    Date: Tuesday, July 7, 2020 @ 15:54:04
  Author: felixonmars
Revision: 659027

archrelease: copy trunk to community-staging-x86_64

Added:
  libantlr3c/repos/community-staging-x86_64/
  libantlr3c/repos/community-staging-x86_64/PKGBUILD
    (from rev 659026, libantlr3c/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: libantlr3c/repos/community-staging-x86_64/PKGBUILD (from rev 659026, libantlr3c/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 15:54:04 UTC (rev 659027)
@@ -0,0 +1,52 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Mathieu Clabaut <mathieu.clabaut at gmail.com>
+# Contributor: Artyom Smirnov <smirnoffjr at gmail.com>
+# Contributor: Alexis Robert <alexis.robert at gmail.com>
+# Contributor: Daniel Nagy <danielnagy at gmx.de>
+
+pkgname=libantlr3c
+pkgver=3.5.2
+pkgrel=4
+pkgdesc='ANother Tool for Language Recognition'
+url='https://www.antlr3.org'
+arch=(x86_64)
+license=(BSD)
+makedepends=(git)
+source=("git+https://github.com/antlr/antlr3.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cd antlr3/runtime/C
+  cat <<EOF> antlr3config.h.in
+#include <stdint.h>
+#include <stdarg.h>
+#include <stdlib.h>
+#include <netinet/in.h>
+#include <netinet/tcp.h>
+#include <sys/stat.h>
+#include <sys/socket.h>
+#include <antlr3defs.h>
+EOF
+  aclocal
+  libtoolize
+  automake --add-missing
+  autoconf
+}
+
+build() {
+  cd antlr3/runtime/C
+
+  ./configure --prefix=/usr --enable-64bit --sysconfdir=/etc
+  make
+}
+
+package() {
+  cd antlr3/runtime/C
+
+  DESTDIR="$pkgdir" make install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+# getver: antlr3.org
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list