[arch-commits] Commit in coin-or-mp/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 16:10:22
  Author: felixonmars
Revision: 659152

archrelease: copy trunk to community-staging-x86_64

Added:
  coin-or-mp/repos/community-staging-x86_64/
  coin-or-mp/repos/community-staging-x86_64/PKGBUILD
    (from rev 659150, coin-or-mp/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: coin-or-mp/repos/community-staging-x86_64/PKGBUILD (from rev 659150, coin-or-mp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 16:10:22 UTC (rev 659152)
@@ -0,0 +1,46 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andreas Radke <andyrtr at archlinux.org>
+# Contributor: spider-mario <spidermario at free.fr>
+# Contributor: Daniel Ehlers <danielehlers at mindeye.net>
+
+pkgname=coin-or-mp
+pkgver=1.8.4
+pkgrel=2
+pkgdesc="C-API library that supports most of the functionality of CLP (Coin LP), CBC (Coin Branch-and-Cut), and CGL (Cut Generation Library) projects"
+arch=(x86_64)
+url="https://projects.coin-or.org/CoinMP"
+license=(EPL)
+groups=(coin-or)
+depends=(coin-or-cbc)
+provides=(coin-mp)
+source=(https://www.coin-or.org/download/source/CoinMP/CoinMP-$pkgver.tgz)
+sha256sums=('3459fb0ccbdd39342744684338984ac4cc153fb0434f4cae8cf74bd67490a38d')
+
+build() {
+  cd CoinMP-$pkgver
+  COIN_SKIP_PROJECTS="Sample" \
+  ./configure --prefix=/usr \
+              --with-osi-lib="$(pkg-config --libs osi)" \
+              --with-osi-incdir="/usr/include/coin/" \
+              --with-clp-lib="$(pkg-config --libs clp)" \
+              --with-clp-incdir="/usr/include/coin/" \
+              --with-cgl-lib="$(pkg-config --libs cgl)" \
+              --with-cgl-incdir="/usr/include/coin/" \
+              --with-cbc-lib="$(pkg-config --libs cbc)" \
+              --with-cbc-incdir="/usr/include/coin/" \
+              --with-coinutils-lib="$(pkg-config --libs coinutils)" \
+              --with-coinutils-incdir="/usr/include/coin/"
+  make
+}
+
+check() {
+  cd CoinMP-$pkgver
+  make test
+}
+
+package() {
+  cd CoinMP-$pkgver/CoinMP
+
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir"/build
+}