[arch-commits] Commit in libpinyin/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 16:38:53
  Author: felixonmars
Revision: 659340

archrelease: copy trunk to community-staging-x86_64

Added:
  libpinyin/repos/community-staging-x86_64/
  libpinyin/repos/community-staging-x86_64/PKGBUILD
    (from rev 659339, libpinyin/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: libpinyin/repos/community-staging-x86_64/PKGBUILD (from rev 659339, libpinyin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 16:38:53 UTC (rev 659340)
@@ -0,0 +1,37 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Yangtse <yangtsesu at gmail.com>
+# Contributor: WU Jun <quark at lihdd dot net>
+
+pkgname=libpinyin
+pkgver=2.3.0
+_modelver=17
+pkgrel=2
+pkgdesc="Library to deal with pinyin"
+arch=('x86_64')
+url="https://github.com/libpinyin/libpinyin"
+license=('GPL')
+depends=('kyotocabinet' 'glib2')
+makedepends=('gnome-common')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/$pkgver.tar.gz"
+        "$pkgname-model$_modelver.text.tar.gz::https://downloads.sourceforge.net/libpinyin/model$_modelver.text.tar.gz")
+noextract=("$pkgname-model$_modelver.text.tar.gz")
+sha512sums=('5cfe2d70c15dc532fa970a28b70da403f2d848747501bdbdf43c481f8165d6290cb1de086d2ef7af653edfe3fb164d4e8d9cf655302e2aa759709e6031b117b2'
+            'd0bf8d476a63e33e292046754161316f00bfea71ebd06fca85b3845fe535431f01458282f505380cae018050aa6a08b14a7bc0684ba372dc79ee14391f47e8a1')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  ln -s "$srcdir"/$pkgname-model$_modelver.text.tar.gz data/model$_modelver.text.tar.gz
+  sed -i "/wget.*model$_modelver\.text\.tar\.gz/ d" data/Makefile.am
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./autogen.sh --prefix=/usr --with-dbm=KyotoCabinet --enable-libzhuyin
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}