[arch-commits] Commit in pax/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 17:01:45
  Author: felixonmars
Revision: 659510

archrelease: copy trunk to community-staging-x86_64

Added:
  pax/repos/community-staging-x86_64/
  pax/repos/community-staging-x86_64/PKGBUILD
    (from rev 659509, pax/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: pax/repos/community-staging-x86_64/PKGBUILD (from rev 659509, pax/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 17:01:45 UTC (rev 659510)
@@ -0,0 +1,41 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+pkgname=pax
+pkgver=20190825
+pkgrel=2
+pkgdesc='Portable Archive Interchange - the POSIX standard archive tool for cpio and tar formats'
+arch=('x86_64')
+url='https://www.mirbsd.org/pax.htm'
+license=('BSD')
+depends=('glibc')
+source=("https://www.mirbsd.org/MirOS/dist/mir/cpio/paxmirabilis-${pkgver}.cpio.gz")
+noextract=("paxmirabilis-${pkgver}.cpio.gz")
+sha256sums=('94c9110e4778d762523c3915b97587b92ae4547129424e34ad4512da4eb09b81')
+
+prepare() {
+    mkdir -p "${pkgname}-${pkgver}/build"
+    bsdtar -x -f "paxmirabilis-${pkgver}.cpio.gz" -C "$pkgname-${pkgver}" --strip-components='1'
+}
+
+build() {
+    cd "${pkgname}-${pkgver}/build"
+    sh ../Build.sh -r -tpax
+    
+    # license
+    sed -n '5,36p' ../pax.h > LICENSE # create file
+    sed -i '1,32s/^.\{,3\}//' LICENSE # erase C comments
+}
+
+package(){
+    # executables
+    install -D -m755 "${pkgname}-${pkgver}/build/pax" -t "${pkgdir}/usr/bin"
+    ln -s pax "${pkgdir}/usr/bin/paxcpio"
+    ln -s pax "${pkgdir}/usr/bin/paxtar"
+    
+    # man pages
+    install -D -m644 "${pkgname}-${pkgver}/build/mans/"*.1 -t "${pkgdir}/usr/share/man/man1"
+    
+    # license
+    install -D -m644 "${pkgname}-${pkgver}/build/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}